iniciar-programa

define-nueva-instruccion gira(z) como repetir z veces gira-izquierda;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion comparar(a) como inicio
        si junto-a-zumbador y no si-es-cero(a) entonces inicio
            coge-zumbador;
            comparar(precede(a));
            deja-zumbador;
        fin sino inicio
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion busca(x) como inicio
        si no junto-a-zumbador entonces inicio
            deja-zumbador;
            si frente-libre entonces inicio
                avanza;
                busca(x);
                gira(2);
                avanza;
                gira(2);
            fin;

            gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                busca(sucede(x));
                gira(2);
                avanza;
                gira(2);
            fin;

            gira(2);
            si frente-libre entonces inicio
                avanza;
                busca(sucede(x));
                gira(2);
                avanza;
                gira(2);
            fin;

            gira-izquierda;

            coge-zumbador;

        fin sino inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    comparar(x);
                fin sino inicio
                    repetir x veces deja-zumbador;
                fin;
                repetir 2 veces deja-zumbador;
            fin sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion quita2 como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;

                apagate;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                quita2;
                sur;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                quita2;
                oeste;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                quita2;
                este;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                quita2; 
                norte;
                avanza;
            fin;
        fin;
    fin;


    inicia-ejecucion
    norte;busca(0);
    este;busca(0);
    oeste;busca(0);
    sur;busca(0);
    quita2;

        apagate;
    termina-ejecucion
finalizar-programa
