iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;

    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
    fin;

    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;

    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;

    define-nueva-instruccion copia como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            copia;
            deja-zumbador;
        fin sino inicio
            deja-zumbador;
            gira(2);
            avanza;
        fin;
    fin;

    define-nueva-instruccion comparar(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            coge-zumbador;
            gira(2);
            avanza;
            deja-zumbador;
            gira(2);
            avanza;
            comparar(precede(n));
        fin sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            gira(2);
            avanza;
            copia;
        fin;
    fin;

    define-nueva-instruccion busqueda(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    repetir 2 veces deja-zumbador;
                    gira(2);
                    avanza;
                    si junto-a-zumbador entonces coge-zumbador;
                    gira(2);
                    avanza;
                    comparar(n);
                fin sino inicio
                    mientras junto-a-zumbador hacer coge-zumbador;
                    repetir n veces deja-zumbador;
                fin;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio
            deja-zumbador;

            si frente-libre entonces inicio
                avanza;
                busqueda(n);
                gira(2);
                avanza;
                gira(2);
            fin;

            gira(1);
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                gira(2);
                avanza;
                gira(2);
            fin;

            gira(2);
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                gira(2);
                avanza;
                gira(2);
            fin;

            gira(1);
            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion laser como inicio
        deja-zumbador;
        norte;
        si frente-libre entonces inicio
            avanza;
            busqueda(1);
            sur;
            avanza;
        fin;

        este;
        si frente-libre entonces inicio
            avanza;
            busqueda(1);
            oeste;
            avanza;
        fin;

       sur;
        si frente-libre entonces inicio
            avanza;
            busqueda(1);
            norte;
            avanza;
        fin;

        oeste;
        si frente-libre entonces inicio
            avanza;
            busqueda(1);
            este;
            avanza;
        fin;
    fin;

    define-nueva-instruccion sobrante como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                apagate;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio
            deja-zumbador;

            norte;
        si frente-libre entonces inicio
            avanza;
            sobrante;
            sur;
            avanza;
        fin;

        este;
        si frente-libre entonces inicio
            avanza;
            sobrante;
            oeste;
            avanza;
        fin;

       sur;
        si frente-libre entonces inicio
            avanza;
            sobrante;
            norte;
            avanza;
        fin;

        oeste;
        si frente-libre entonces inicio
            avanza;
            sobrante;
            este;
            avanza;
        fin;

        fin;
    fin;

    inicia-ejecucion
        laser;
        coge-zumbador;
        sobrante;
        apagate;
    termina-ejecucion
finalizar-programa
