iniciar-programa
define-prototipo-instruccion busca(x);
define-nueva-instruccion gira(q) como repetir q veces gira-izquierda;
define-nueva-instruccion compara(x) como inicio
    si no si-es-cero(x) entonces inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara(precede(x));
            deja-zumbador;
        fin;
    fin sino inicio
        mientras junto-a-zumbador hacer coge-zumbador;
    fin;
fin;
define-nueva-instruccion orientacion(x) como inicio
    gira(1);
    si frente-libre entonces inicio
        avanza;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
                busca(sucede(x));
            fin sino inicio
                deja-zumbador;
            fin;
            gira(2);
            avanza;
            gira(2);
        fin sino inicio
            busca(sucede(x));
            gira(2);
            avanza;
            gira(2);
        fin;
    fin;
    gira(2);
    si frente-libre entonces inicio
        avanza;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
                busca(sucede(x));
            fin sino inicio
                deja-zumbador;
            fin;
            gira(2);
            avanza;
            gira(2);
        fin sino inicio
            busca(sucede(x));
            gira(2);
            avanza;
            gira(2);
        fin;
    fin;
    gira(1);
    si junto-a-zumbador entonces coge-zumbador;
fin;
define-nueva-instruccion busca(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                compara(x);
            fin sino inicio
                repetir x veces deja-zumbador;
            fin;
            si junto-a-zumbador entonces coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
            fin sino inicio
                deja-zumbador;
                apagate;
            fin;
            repetir 2 veces deja-zumbador;
        fin sino inicio
            deja-zumbador;
        fin;
    fin sino inicio
        deja-zumbador;
        si frente-libre entonces inicio
            avanza;
            busca(x);
            gira(2);
            avanza;
            gira(2);
        fin;
        orientacion(x);
    fin;
fin;
define-nueva-instruccion ubica(n) como inicio
    mientras no orientado-al-norte hacer gira-izquierda;
    repetir n veces gira-izquierda;
    si frente-libre entonces inicio
        avanza;
        si no junto-a-zumbador entonces inicio
            busca(0);
        fin;
        gira(2);
        avanza;
        gira(2);
    fin;
fin;
define-nueva-instruccion come como inicio
    mientras frente-libre y no junto-a-zumbador hacer avanza;
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
        fin sino inicio
            come;
        fin;
    fin sino inicio
        gira(1);
        si frente-libre entonces inicio
        avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        gira(2);
        come;
        fin;
    fin;
fin;
    inicia-ejecucion
    ubica(0);
    ubica(1);
    ubica(2);
    ubica(3);
    mientras no orientado-al-sur hacer gira-izquierda;
    mientras frente-libre hacer avanza;
    mientras no orientado-al-oeste hacer gira-izquierda;
    mientras frente-libre hacer avanza;
    gira(2);
    come;
        apagate;
    termina-ejecucion
finalizar-programa
