iniciar-programa
   define-nueva-instruccion gira(n) como inicio
      repetir n veces
         gira-izquierda;
   fin;
   define-nueva-instruccion coge(n) como inicio
      si no si-es-cero(n) entonces inicio
         si junto-a-zumbador entonces inicio
            coge-zumbador;
            coge(precede(n));
            deja-zumbador;
         fin;
      fin
      sino inicio
         mientras junto-a-zumbador hacer
            coge-zumbador;
      fin;
   fin;
   define-nueva-instruccion busca(n) como inicio
      si no-junto-a-zumbador entonces inicio
         deja-zumbador;
         si frente-libre entonces inicio
            avanza;
            busca(n);
            gira(2);
            avanza;
            gira(2);
         fin;
         si izquierda-libre entonces inicio
            gira(1);
            avanza;
            busca(sucede(n));
            gira(2);
            avanza;
            gira(1);
         fin;
         si derecha-libre entonces inicio
            gira(3);
            avanza;
            busca(sucede(n));
            gira(2);
            avanza;
            gira(3);
         fin;
         coge-zumbador;
      fin
      sino inicio
         coge-zumbador;
         si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
               repetir n veces
                  deja-zumbador;
               deja-zumbador;
            fin
            sino inicio
               deja-zumbador;
               coge(n);
               deja-zumbador;
            fin;
         fin
         sino inicio
            deja-zumbador;
         fin;
      fin;
   fin;
   define-nueva-instruccion toma como inicio
      mientras no-orientado-al-oeste hacer
         gira(1);
      mientras frente-libre hacer
         avanza;
      mientras no-orientado-al-sur hacer
         gira(1);
      mientras frente-libre hacer
         avanza;
      gira(1);
      mientras orientado-al-este hacer inicio
         mientras frente-libre hacer inicio
            si junto-a-zumbador entonces
               coge-zumbador;
            avanza;
         fin;
         si junto-a-zumbador entonces
            coge-zumbador;
         gira(2);
         mientras frente-libre hacer
            avanza;
         gira(3);
         si frente-bloqueado entonces
            apagate;
         avanza;
         gira(3);
      fin;
   fin;
   inicia-ejecucion
      deja-zumbador;
      repetir 4 veces inicio
         si frente-libre entonces inicio
            avanza;
            busca(0);
            gira(2);
            avanza;
            gira(2);
         fin;
         gira(1);
      fin;
      toma;
      apagate;
   termina-ejecucion
finalizar-programa