iniciar-programa

define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

define-nueva-instruccion regresar(a) como inicio
    si no(si-es-cero(a)) y junto-a-zumbador entonces inicio
        coge-zumbador;
        regresar(precede(a));
    fin sino inicio
        repetir a veces deja-zumbador;
    fin;
fin;

define-nueva-instruccion comprobar(b) como inicio
    si no(si-es-cero(b)) y junto-a-zumbador entonces inicio
        coge-zumbador;
        comprobar(precede(b));
    fin sino inicio
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
        fin sino inicio
            si no-junto-a-zumbador y no(si-es-cero(b)) entonces inicio
                repetir b veces deja-zumbador;
            fin;
        fin;
    fin;
fin;

define-nueva-instruccion bp(x) como inicio
    si no-junto-a-zumbador entonces inicio
        deja-zumbador;
        repetir 2 veces inicio
            si frente-libre entonces inicio
                avanza;
                bp(x);
                gira(2);
                avanza;
                gira(2);
            fin;
            gira(1);
            si frente-libre entonces inicio
                avanza;
                bp(sucede(x));
                gira(2);
                avanza;
                gira(2);
            fin;
            gira(1);
        fin;
        coge-zumbador;
    fin sino inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces repetir x veces deja-zumbador;
            comprobar(x);
            si no-junto-a-zumbador entonces inicio
                repetir x veces deja-zumbador;
            fin sino inicio
                regresar(x);
            fin;
            repetir 2 veces deja-zumbador;
        fin sino inicio
            deja-zumbador;
        fin;
    fin;
fin;

define-nueva-instruccion final como inicio
    mientras derecha-libre o frente-libre hacer inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                apagate;
            fin sino inicio
                deja-zumbador;
            fin;
        fin;
        mientras frente-libre hacer inicio
            avanza;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    apagate;
                fin sino inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
        si derecha-libre entonces inicio
            gira(2);
            mientras frente-libre hacer avanza;
            gira(1);
            avanza;
            gira(1);
        fin;
    fin;
fin;

    inicia-ejecucion

    repetir 4 veces inicio
        si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
                gira(2);
                avanza;
                gira(2);
            fin sino inicio
                gira(2);
                avanza;
                gira(2);
                bp(0);
            fin;
        fin;
        gira(1);
    fin;
    mientras no-orientado-al-sur hacer gira(1);
    repetir 2 veces inicio
    mientras frente-libre hacer avanza;
    gira(3);
    fin;
    final;

        apagate;
    termina-ejecucion
finalizar-programa
