iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion menor(x) como inicio
        si no(si-es-cero(x)) entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                menor(precede(x));
                deja-zumbador;
            fin;
        fin sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion busca(rebotes) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    (*Ya hemos llegado por lo tanto verificamos el menor*)
                    menor(rebotes);
                    repetir 2 veces deja-zumbador;
                fin sino inicio
                    (*No se habia llegado dejamos el numero de rebotes*)
                    si si-es-cero(precede(rebotes)) entonces inicio
                        deja-zumbador;    
                        apagate;
                    fin;
                    repetir sucede(sucede(rebotes)) veces deja-zumbador;
                fin;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio
            deja-zumbador;
            (*revisamos frente, izquierda, derecha*)
            si frente-libre entonces inicio
                avanza;
                busca(rebotes);
                gira(2);
                avanza;
                gira(2);
            fin;

            gira(1);
            si frente-libre entonces inicio
                avanza;
                busca(sucede(rebotes));
                gira(2);
                avanza;
                gira(1);
            fin sino inicio
                gira(3);
            fin;

            gira(3);
            si frente-libre entonces inicio
                avanza;
                busca(sucede(rebotes));
                gira(2);
                avanza;
                gira(3);
            fin sino inicio
                gira(1);
            fin;

            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion quitar_beepers como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                apagate;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio
            deja-zumbador;
            repetir 4 veces inicio
                gira-izquierda;
                si frente-libre entonces inicio
                    avanza;
                    quitar_beepers;
                    gira(2);
                    avanza;
                    gira(2);
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion ubica(n) como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
        repetir n veces gira-izquierda;
        busca(0);
    fin;
    inicia-ejecucion
        ubica(0);
        ubica(1);
        ubica(2);
        ubica(3);
        quitar_beepers;
        apagate;
    termina-ejecucion
finalizar-programa
