iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion compara (n) como inicio
        si si-es-cero (n) entonces inicio
            mientras junto-a-zumbador hacer
                coge-zumbador;
        fin
        sino inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                compara (precede(n));
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion busca (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no-junto-a-zumbador entonces inicio
                    repetir n veces
                        deja-zumbador;
                    repetir 2 veces
                        deja-zumbador;
                fin
                sino inicio
                    compara (n);
                    repetir 2 veces
                        deja-zumbador;
                fin;
            fin
            sino inicio
                deja-zumbador;
            fin;
        fin
        sino inicio
            si orientado-al-norte o orientado-al-sur entonces inicio
                deja-zumbador;
                norte;
                si frente-libre entonces inicio
                    avanza;
                    busca (n);
                    sur;
                    avanza;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    busca (sucede(n));
                    oeste;
                    avanza;
                fin;
                sur;
                si frente-libre entonces inicio
                    avanza;
                    busca (n);
                    norte;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    busca (sucede(n));
                    este;
                    avanza;
                fin;
                coge-zumbador;
            fin
            sino inicio
                si orientado-al-este o orientado-al-oeste entonces inicio
                    deja-zumbador;
                    norte;
                    si frente-libre entonces inicio
                        avanza;
                        busca (sucede(n));
                        sur;
                        avanza;
                    fin;
                    este;
                    si frente-libre entonces inicio
                        avanza;
                        busca (n);
                        oeste;
                        avanza;
                    fin;
                    sur;
                    si frente-libre entonces inicio
                        avanza;
                        busca (sucede(n));
                        norte;
                        avanza;
                    fin;
                    oeste;
                    si frente-libre entonces inicio
                        avanza;
                        busca (n);
                        este;
                        avanza;
                    fin;
                    coge-zumbador;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion busca2 como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                apagate;
            fin
            sino inicio
                deja-zumbador;
            fin;
        fin
        sino inicio
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                busca2;
                sur;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                busca2;
                oeste;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                busca2;
                norte;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                busca2;
                este;
                avanza;
            fin;
        fin;
    fin;
    inicia-ejecucion
        norte;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                sur;
                avanza;
                norte;
                busca (0);
            fin
            sino inicio
                sur;
                avanza;
            fin;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                oeste;
                avanza;
                este;
                busca (0);
            fin
            sino inicio
                oeste;
                avanza;
            fin;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                norte;
                avanza;
                sur;
                busca (0);
            fin
            sino inicio
                norte;
                avanza;
            fin;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                este;
                avanza;
                oeste;
                busca (0);
            fin
            sino inicio
                este;
                avanza;
            fin;
        fin;
        busca2;
        apagate;
    termina-ejecucion
finalizar-programa