iniciar-programa
define-nueva-instruccion avanzar(n) como si si-es-cero(n) entonces mientras frente-libre hacer avanza sino repetir n veces si frente-libre entonces avanza;
define-nueva-instruccion girar(n) como repetir n veces gira-izquierda;
define-nueva-instruccion dejar(n) como si si-es-cero(n) entonces mientras algun-zumbador-en-la-mochila hacer deja-zumbador sino repetir n veces si algun-zumbador-en-la-mochila entonces deja-zumbador;
define-nueva-instruccion coger(n) como si si-es-cero(n) entonces mientras junto-a-zumbador hacer coge-zumbador sino repetir n veces si junto-a-zumbador entonces coge-zumbador;
define-nueva-instruccion al-norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion al-sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion al-oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion al-este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion min(n) como inicio
    si (no si-es-cero(n)) y junto-a-zumbador entonces inicio
        coge-zumbador;
        min(precede(n));
        deja-zumbador;
    fin sino mientras junto-a-zumbador hacer coge-zumbador;
fin;
define-nueva-instruccion busq(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces dejar(203) sino deja-zumbador;
            deja-zumbador;
            min(n);
        fin sino deja-zumbador;
    fin sino inicio
        deja-zumbador;
        si frente-libre entonces inicio
            avanza;
            busq(n);
            gira-izquierda;
            gira-izquierda;
            avanza;
            gira-izquierda;
            gira-izquierda;
        fin;
        gira-izquierda;
        si frente-libre entonces inicio
            avanza;
            busq(sucede(n));
            gira-izquierda;
            gira-izquierda;
			avanza;
            gira-izquierda;
            gira-izquierda;
        fin;
        gira-izquierda;
        gira-izquierda;
        si frente-libre entonces inicio
            avanza;
            busq(sucede(n));
            gira-izquierda;
            gira-izquierda;
            avanza;
            gira-izquierda;
            gira-izquierda;
        fin;
        gira-izquierda;
        coge-zumbador;
    fin;
fin;
    inicia-ejecucion
        repetir 4 veces inicio
            busq(3);
            gira-izquierda;
        fin;
        al-sur;
        avanzar(0);
        al-oeste;
        avanzar(0);
        al-este;
        mientras frente-libre hacer inicio
            al-norte;
            mientras frente-libre hacer inicio
                si junto-a-zumbador entonces inicio
                    coger(1);
                    si junto-a-zumbador entonces coger(2);
                fin;
                avanzar(1);
            fin;
            si junto-a-zumbador entonces inicio
                coger(1);
                si junto-a-zumbador entonces coger(2);
            fin;
            girar(2);
            avanzar(0);
            al-este;
            avanzar(1);
        fin;
        al-norte;
            mientras frente-libre hacer inicio
                si junto-a-zumbador entonces inicio
                    coger(1);
                    si junto-a-zumbador entonces coger(2);
                fin;
                avanzar(1);
            fin;
            si junto-a-zumbador entonces inicio
                coger(1);
                si junto-a-zumbador entonces coger(2);
            fin;
            girar(2);
            avanzar(0);
        apagate;
    termina-ejecucion
finalizar-programa
