iniciar-programa

    define-nueva-instruccion norte como
        mientras no-orientado-al-norte hacer
            gira-izquierda;

    define-nueva-instruccion sur como
        mientras no-orientado-al-sur hacer
            gira-izquierda;

    define-nueva-instruccion oeste como
        mientras no-orientado-al-oeste hacer
            gira-izquierda;

    define-nueva-instruccion este como
        mientras no-orientado-al-este hacer
            gira-izquierda;

    define-nueva-instruccion ir22 como inicio
        sur;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
        norte;
        avanza;
        este;
        avanza;
    fin;

    define-nueva-instruccion ir_a_colados (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ir_a_colados (sucede (n));
        fin
        sino inicio
            este;
            repetir precede (n) veces inicio
                si frente-libre entonces inicio
                    avanza;
                fin
                sino inicio
                    sur;
                fin;
            fin;
            si no-orientado-al-sur entonces inicio
                oeste;
                avanza;
                sur;
            fin;
            avanza;
        fin;
    fin;

    define-nueva-instruccion recorre_fila como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recorre_fila;
            deja-zumbador;
        fin
        sino inicio
            oeste;
            si frente-libre entonces
                avanza;
            si junto-a-zumbador entonces inicio
                recorre_fila;
                este;
                avanza;
            fin
            sino inicio
                oeste;
                mientras no-junto-a-zumbador y frente-libre hacer
                    avanza;
                si junto-a-zumbador entonces inicio
                    este;
                    avanza;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion quitar (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            quitar (n);
            deja-zumbador;
        fin
        sino inicio
            oeste;
            si no si-es-cero (n) entonces inicio
                avanza;
                quitar (precede (n));
                este;
                si frente-libre entonces
                    avanza;
            fin
            sino inicio
                este;
                mientras no-junto-a-zumbador y frente-libre hacer
                    avanza;
                mientras junto-a-zumbador y frente-libre hacer
                    avanza;
                si no-junto-a-zumbador entonces inicio
                    oeste;
                    avanza;
                fin;
                si junto-a-zumbador entonces
                    recorre_fila;
                si junto-a-zumbador entonces inicio
                    este;
                    avanza;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion contar_gandaya (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            contar_gandaya (sucede (n));
        fin
        sino inicio
            oeste;
            avanza;
            ir_a_colados (0);
            quitar (precede (n));
        fin;
    fin;

    inicia-ejecucion
        ir22;
        contar_gandaya (0);
        apagate;
    termina-ejecucion
finalizar-programa