iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion dejalo(n) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            dejalo(sucede(n));
        fin
    sino
        inicio
            norte;
            avanza;
            repetir n veces deja-zumbador;
            sur;
            avanza;
            oeste;
        fin;
    fin;

define-nueva-instruccion al-final como
    inicio
        avanza;
        dejalo(0);
    fin;

define-nueva-instruccion sacalo (n) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            sacalo(sucede(n));
        fin
    sino
        inicio
            oeste;
            avanza;
            sur;
            avanza;
            este;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si frente-bloqueado y no-junto-a-zumbador entonces
            inicio
                oeste;
            mientras frente-libre y no-junto-a-zumbador hacer avanza;
            fin;
        si junto-a-zumbador entonces coge-zumbador;
            sur;
            avanza;
            oeste;
        fin;
        si no si-es-cero (n) entonces al-final;
    fin;

define-nueva-instruccion posicion(donde) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            posicion(sucede(donde));
        fin
    sino
        inicio
            este;
        si no si-es-cero (donde) entonces repetir precede (donde) veces avanza;
            deja-zumbador;
            norte;
            avanza;
            oeste;
        mientras frente-libre hacer avanza;
            este;
            avanza;
            sacalo(0);
        fin;
    fin;

define-nueva-instruccion acomodando (x) como
    inicio
    si no si-es-cero (x) entonces
        inicio
            deja-zumbador;
        fin sino si frente-libre entonces avanza;
    fin;

define-nueva-instruccion reacomoda (x) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            reacomoda(sucede(x));
        fin
    sino
        inicio
        si frente-libre entonces avanza;
        si junto-a-zumbador entonces reacomoda (0) sino
            inicio
                sur;
            si frente-libre entonces avanza;
                oeste;
            mientras frente-libre hacer avanza;
                este;
            mientras junto-a-zumbador y frente-libre hacer avanza;
            fin;
        fin;
        acomodando(x);
    fin;

define-nueva-instruccion muevelo(n) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            muevelo(sucede(n));
        fin
    sino
        inicio
            norte;
            avanza;
            repetir n veces deja-zumbador;
            sur;
            repetir 2 veces avanza;
            oeste;
            avanza;
        fin;
    fin;

define-nueva-instruccion arranca como
    inicio
        norte;
        avanza;
        este;
        avanza;
        muevelo(0);
        norte;
        avanza;
        posicion(0);
        este;
    mientras frente-libre hacer avanza;
        oeste;
    mientras frente-libre y no-junto-a-zumbador hacer avanza;
        reacomoda(0);
    mientras frente-libre hacer avanza;
        norte;
        avanza;
        oeste;
    mientras no-junto-a-zumbador y frente-libre hacer avanza;
    si junto-a-zumbador entonces reacomoda(0);
        oeste;
    mientras frente-libre hacer avanza;
        sur;
    si frente-libre entonces avanza;
    fin;

    inicia-ejecucion
        arranca;
        apagate;
    termina-ejecucion
finalizar-programa
