iniciar-programa
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion busca2(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        busca2(sucede(n));
    fin sino inicio
        oeste;avanza;sur;avanza;este;
        mientras junto-a-zumbador hacer avanza;
        oeste;
        repetir n veces avanza;
        este;
        sal-de-instruccion;
    fin;
fin;
define-nueva-instruccion busca(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        busca(sucede(n));
    fin sino inicio
        sur;avanza;este;
        repetir n veces avanza;
        oeste;avanza;este;
    fin;
fin;
define-nueva-instruccion sube como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        sube;
        deja-zumbador;
    fin sino inicio
        avanza;
        si junto-a-zumbador entonces avanza;
    fin;
fin;
define-nueva-instruccion acomoda(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        acomoda(sucede(n));
    fin sino inicio
        si frente-libre entonces avanza;
        si junto-a-zumbador entonces acomoda(0);
        mientras no-junto-a-zumbador y orientado-al-oeste hacer inicio
            mientras no-junto-a-zumbador y orientado-al-oeste hacer inicio
                si frente-bloqueado y orientado-al-oeste entonces inicio
                    este;
                fin sino avanza;
            fin;
            si orientado-al-oeste entonces inicio
                este; avanza;
            fin;
        fin;
        si no-junto-a-zumbador entonces inicio
            repetir n veces deja-zumbador;
            avanza;
        fin;

    fin;
fin;
define-nueva-instruccion lleva(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        lleva(sucede(n));
    fin sino inicio
        si frente-libre entonces avanza;
        si junto-a-zumbador entonces lleva(0);
        si no-junto-a-zumbador y orientado-al-oeste entonces inicio
            mientras frente-libre hacer avanza;
            sur;
            avanza;
            este;
            mientras junto-a-zumbador hacer avanza;
        fin;
        si no-junto-a-zumbador entonces inicio
            repetir n veces deja-zumbador;
            si frente-libre entonces avanza;
        fin;
    fin;
fin;
define-nueva-instruccion baja como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        baja;
        deja-zumbador;
    fin sino inicio
        mientras frente-libre hacer avanza;
    fin;
fin;
    inicia-ejecucion
    norte;avanza;
    busca(0);
    norte;
    sube;
    oeste;
    mientras frente-libre hacer avanza;
    sur;mientras frente-libre hacer avanza;norte;avanza;este;avanza;
    busca2(0);
    mientras junto-a-zumbador hacer inicio
        norte;
        sube;
        sur;avanza;este;
        avanza;
    fin;
    norte;avanza;si no-junto-a-zumbador entonces avanza;
    sur;baja;este;
    mientras junto-a-zumbador y orientado-al-este hacer inicio
        si frente-libre y orientado-al-este entonces inicio
            avanza;
        fin sino oeste;
    fin;
    si no-junto-a-zumbador entonces inicio
        oeste;avanza;
    fin;
    acomoda(0);oeste;
    mientras frente-libre hacer avanza;
    norte;avanza;este;
    mientras no-junto-a-zumbador hacer inicio
        si frente-libre entonces inicio
        avanza;
        fin sino apagate;
    fin;
    mientras junto-a-zumbador hacer avanza;oeste;
    avanza;lleva(0);
        apagate;
    termina-ejecucion
finalizar-programa
