iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion subir como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            subir;
            deja-zumbador;
        fin sino
        inicio
            norte;
            avanza;
            sur;
        fin;
    fin;

    define-nueva-instruccion persona como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            persona;
            si frente-bloqueado entonces este;
            si frente-libre entonces avanza;
         fin sino sur;
     fin;

    define-nueva-instruccion colados como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            colados;
            avanza;
            subir;
            avanza;
            oeste;
        fin sino
        inicio
            avanza;
            persona;
            oeste;

        fin;
    fin;

    define-nueva-instruccion recorrer como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            recorrer;
            deja-zumbador;
        fin sino
        inicio
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si junto-a-zumbador entonces
            inicio
                este;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion acomodar como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            acomodar;
            deja-zumbador;
        fin sino
        inicio
            oeste;
            mientras frente-libre hacer avanza;
            sur;
            avanza;
            este;
            mientras junto-a-zumbador hacer avanza;
        fin;
    fin;

    define-nueva-instruccion todo como
    inicio
        norte;
        avanza;
        este;
        avanza;
        oeste;
        colados;
        este;
        mientras frente-libre hacer
        inicio
            este;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si junto-a-zumbador entonces oeste;
            si junto-a-zumbador entonces recorrer;
            este;
            si frente-libre entonces avanza;
         fin;
        si frente-bloqueado entonces
        inicio
            oeste;
            mientras frente-libre hacer avanza;
            norte;
            avanza;
            este;
            mientras no-junto-a-zumbador hacer avanza;
        fin;
        mientras frente-libre o junto-a-zumbador hacer
        inicio
            si junto-a-zumbador entonces acomodar;
            oeste;
            mientras frente-libre hacer avanza;
            norte;
            avanza;
            este;
            mientras frente-libre y no-junto-a-zumbador hacer avanza;
        fin;
     fin;

    inicia-ejecucion
        todo;
        apagate;
    termina-ejecucion
finalizar-programa
