iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion gandaya(n) como
inicio
  si junto-a-zumbador entonces
    inicio
      coge-zumbador;
      gandaya(sucede(n));
    fin
  sino
    inicio
      norte;
      avanza;
      este;
      repetir precede (n) veces avanza;
      deja-zumbador;

    fin;
fin;
define-nueva-instruccion toma(i) como                                           
inicio
  si junto-a-zumbador entonces
    inicio
      coge-zumbador;
      toma(sucede(i));
    fin
  sino
    inicio
       norte;
       avanza;
       repetir i veces deja-zumbador;
    fin;
fin;
define-nueva-instruccion levanta(n) como
inicio
  si junto-a-zumbador entonces
    inicio
      coge-zumbador;
      levanta(sucede(n));
    fin
  sino
    inicio
      oeste;
      avanza;
      norte;
      avanza;
      este;
      mientras no-junto-a-zumbador y frente-libre hacer avanza;
      si junto-a-zumbador entonces
        inicio
          sur;
          repetir 2 veces avanza;
          oeste;
          si frente-libre entonces avanza;
          repetir n veces
            inicio
              toma(0);
              sur;
              avanza;
              oeste;
              si frente-libre entonces avanza;
            fin;
        fin;
    fin;
fin;

define-nueva-instruccion arriba como
inicio
  oeste;
  mientras frente-libre hacer avanza;
  sur;
  avanza;
  este;
  mientras junto-a-zumbador y frente-libre hacer avanza;
fin;

define-nueva-instruccion ordenafila(n) como
inicio
  si junto-a-zumbador entonces
    inicio
      coge-zumbador;
      ordenafila(sucede(n));
    fin
  sino
    inicio
      si no-orientado-al-este entonces
        inicio
          si frente-libre entonces avanza;
          si no-junto-a-zumbador y izquierda-bloqueada entonces
            inicio
              oeste;
              mientras frente-libre hacer avanza;
              este;
              mientras junto-a-zumbador y frente-libre hacer avanza;
            fin
          sino si izquierda-libre y no-junto-a-zumbador entonces arriba;
          ordenafila(0);
        fin;
      si no si-es-cero(n) entonces inicio
          este;
          repetir n veces deja-zumbador;
         si frente-libre entonces avanza;
      fin;
    fin;
fin;

    inicia-ejecucion
        norte;
        avanza;
        si no-junto-a-zumbador entonces apagate;
        gandaya(0);
        oeste;
        mientras frente-libre hacer avanza;
        sur;
        avanza;
        este;
        avanza;
        si no-junto-a-zumbador entonces apagate;
        levanta(0);
        sur;
        mientras frente-libre hacer avanza;
        este;
        mientras frente-libre hacer avanza;
        oeste;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        ordenafila(0);
        oeste;
        mientras frente-libre hacer avanza;
        norte;
        avanza;
        este;
        mientras frente-libre hacer avanza;
        oeste;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        ordenafila(0);
        apagate;
    termina-ejecucion
finalizar-programa
 