iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;


    define-nueva-instruccion ubicar como inicio
        norte;
        avanza;
        este;
        si frente-libre entonces avanza;
        oeste;
    fin;

    define-nueva-instruccion tortillas(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            tortillas(sucede(n));
        fin sino inicio
            repetir precede(n) veces avanza;
        fin;
    fin;

    define-nueva-instruccion repartir como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            repartir;
            deja-zumbador;
        fin sino inicio
            norte;
            avanza;
        fin;
    fin;

    define-nueva-instruccion recoger como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoger;
            avanza;
            repartir;
            sur;
            avanza;
            oeste;
        fin sino inicio
            mientras frente-libre hacer avanza;
            este;
            tortillas(0);
            sur;
            avanza;
            oeste;
        fin;
    fin;

    define-nueva-instruccion acomodar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            acomodar(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    acomodar(0);
                fin sino inicio
                    sur;
                    avanza;
                    oeste;
                    mientras frente-libre hacer avanza;
                    este;
                    mientras junto-a-zumbador y frente-libre hacer avanza;
                fin;
            fin sino inicio
                sur;
                avanza;
                oeste;
                mientras frente-libre hacer avanza;
                este;
                mientras junto-a-zumbador y frente-libre hacer avanza;
            fin;
            si orientado-al-este entonces inicio
                repetir n veces deja-zumbador;
                si frente-libre entonces avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion final(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            final(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    final(0);
                fin sino inicio
                    mientras no junto-a-zumbador y frente-libre hacer avanza;
                    este;
                    si junto-a-zumbador entonces avanza;
                fin;
            fin;
            si orientado-al-este entonces inicio
                repetir n veces deja-zumbador;
                si frente-libre entonces avanza;
            fin;
        fin;
    fin;

    inicia-ejecucion
        ubicar;
        recoger;
        este;
        mientras no junto-a-zumbador y frente-libre hacer avanza;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        oeste;
        si no junto-a-zumbador entonces avanza;
        final(0);
        ubicar;
        este;
        mientras frente-libre hacer avanza;
        oeste;
        mientras no junto-a-zumbador y frente-libre hacer avanza;
        acomodar(0);
        apagate;
    termina-ejecucion
finalizar-programa
