iniciar-programa

define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion persona(z) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            persona(sucede(z));
        fin sino inicio
            sur;
            avanza;
            este;
            repetir precede(z) veces avanza;
            oeste;
        fin;
    fin;

    define-nueva-instruccion avanzan como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            avanzan;
            deja-zumbador;
        fin sino inicio
            avanza;
            si junto-a-zumbador entonces inicio
                avanzan;
                avanza;
            fin sino inicio
                mientras no-junto-a-zumbador y frente-libre hacer inicio
                    avanza;
                fin;
                este;
                si junto-a-zumbador entonces inicio
                    avanza;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion mueve(n) como inicio
        si no si-es-cero(n) entonces inicio
           si junto-a-zumbador entonces inicio
               coge-zumbador;
               mueve(n);
               deja-zumbador;
           fin sino inicio
               si frente-libre entonces inicio
                   avanza;
                   mueve(precede(n));
                   avanza;
               fin sino inicio
                   mueve(precede(n));
                   avanza;
               fin;
            fin;
        fin sino inicio
            este;
            avanza;
            mientras no-junto-a-zumbador hacer inicio
                avanza;
            fin;
            mientras junto-a-zumbador y frente-libre hacer inicio
                avanza;
            fin;
            oeste;
            si no-junto-a-zumbador entonces inicio
                avanza;
            fin;
            avanzan;
        fin;
    fin;

    define-nueva-instruccion colados(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            colados(sucede(x));
        fin sino inicio
            oeste;
            avanza;
            persona(0);
            avanza;
            mueve(x);
        fin;
    fin;

    inicia-ejecucion
        norte;
        avanza;
        este;
        avanza;
        colados(0);
        apagate;
    termina-ejecucion
finalizar-programa
