iniciar-programa
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;

    define-nueva-instruccion media-vuelta como inicio
        repetir 2 veces gira-izquierda;
    fin;

    define-nueva-instruccion PosicionDeLaPersona como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            PosicionDeLaPersona;
            avanza;
        fin
        sino inicio
            gira-izquierda;
            avanza;
            gira-izquierda;
            avanza;
        fin;
    fin;

    define-nueva-instruccion moverGente como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            moverGente;
            deja-zumbador;
        fin
        sino inicio
            gira-izquierda;
            avanza;
            media-vuelta;
        fin;
    fin;

    define-nueva-instruccion PersonasColadas(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            PersonasColadas(sucede(n));
            este;
            mientras no-junto-a-zumbador hacer avanza;
            moverGente;
            avanza;
            gira-izquierda;
        fin
        sino inicio
            media-vuelta;
            avanza;
            coge-zumbador;
            PosicionDeLaPersona;
            media-vuelta;
            repetir n veces avanza;
        fin;
    fin;

    define-nueva-instruccion avanzargente como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            avanzargente;
            deja-zumbador;
        fin
        sino inicio
            media-vuelta;
            mientras no junto-a-zumbador y frente-libre hacer avanza;
            media-vuelta;
            si junto-a-zumbador entonces avanza;
        fin;
    fin;

    define-nueva-instruccion recorrerGente(m) como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            avanza;
            recorrerGente(sucede(m));
            mientras no junto-a-zumbador hacer avanza;
            Avanzargente;
            avanza;
        fin
        sino inicio
            media-vuelta;
        fin;
    fin;

    define-nueva-instruccion Ultimo como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            Ultimo;
            deja-zumbador;
        fin
        sino inicio
            mientras no-orientado-al-sur hacer gira-izquierda;
            avanza;
            gira-izquierda;
            mientras junto-a-zumbador hacer avanza;
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion acomodarLaGente como inicio
        si junto-a-zumbador entonces inicio
            avanza;
            acomodarLaGente;
            mientras no-junto-a-zumbador hacer avanza;
            Ultimo;
            avanza;
            gira-izquierda;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            mientras junto-a-zumbador y frente-libre hacer avanza;
            media-vuelta;
        fin
        sino inicio
            media-vuelta;
            si no-junto-a-zumbador entonces avanza;
            mientras frente-libre y junto-a-zumbador hacer avanza;
            media-vuelta;
        fin;
    fin;

    inicia-ejecucion
        mientras no-orientado-al-norte hacer gira-izquierda;
        avanza;
        mientras no-orientado-al-este hacer gira-izquierda;
        avanza;
        PersonasColadas(1);
        si frente-bloqueado entonces apagate;
        mientras frente-libre hacer avanza;
        media-vuelta;
        mientras no-junto-a-zumbador hacer avanza;
        recorrerGente(1);
        gira-izquierda;
        si frente-libre entonces avanza;
        gira-izquierda;
        mientras no-junto-a-zumbador hacer avanza;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        media-vuelta;
        si no-junto-a-zumbador entonces avanza;
        acomodarLaGente;
        apagate;
    termina-ejecucion
finalizar-programa
