iniciar-programa
    define-nueva-instruccion vuelta como repetir 2 veces gira-izquierda;
    define-nueva-instruccion derecha como repetir 3 veces gira-izquierda;
    define-nueva-instruccion lugar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            lugar;
            avanza;
        fin;
    fin;
    define-nueva-instruccion saca como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            saca;
            deja-zumbador;
        fin
        sino inicio
            derecha;
            avanza;
        fin;
    fin;
    define-nueva-instruccion colados(z) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            colados(sucede(z));
        fin
        sino inicio
            mientras no-junto-a-zumbador hacer avanza;
            coge-zumbador;
            derecha;
            avanza;
            derecha;
            repetir z veces inicio
                avanza;
                saca;
                vuelta;
                avanza;
                derecha;
            fin;
        fin;
    fin;
    define-nueva-instruccion mueve como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mueve;
            deja-zumbador;
        fin
        sino inicio
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si junto-a-zumbador entonces inicio
                vuelta;
                avanza;
                vuelta;
            fin;
        fin;
    fin;
    define-nueva-instruccion recorre(x) como inicio
        si junto-a-zumbador y frente-libre entonces inicio
            si frente-libre entonces avanza;
            si frente-bloqueado entonces inicio
                recorre(sucede(sucede(x)));
            fin
            sino inicio
                recorre(sucede(x));
            fin;
        fin
        sino inicio
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
                vuelta;
                avanza;
            fin
            sino inicio
                vuelta;
            fin;
            mientras junto-a-zumbador hacer avanza;
            vuelta;
            avanza;
            vuelta;
            repetir x veces  inicio
                mueve;
                vuelta;
                avanza;
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
                vuelta;
            fin;
        fin;
    fin;
    define-nueva-instruccion final como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            final;
            deja-zumbador;
        fin
        sino inicio
            derecha;
            avanza;
            si junto-a-zumbador entonces inicio
                gira-izquierda;
                mientras junto-a-zumbador hacer avanza;
            fin
            sino inicio
                gira-izquierda;
                mientras no-junto-a-zumbador hacer avanza;
                vuelta;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion manda(v) como inicio
        si junto-a-zumbador entonces inicio
            avanza;
            manda(sucede(v));
        fin
        sino inicio
            deja-zumbador;
            vuelta;
            mientras junto-a-zumbador y frente-libre hacer avanza;
            vuelta;
            si no-junto-a-zumbador entonces avanza;
            repetir v veces inicio
                final;
                vuelta;
                mientras frente-libre hacer avanza;
                derecha;
                avanza;
                derecha;
                mientras no-junto-a-zumbador hacer avanza;
            fin;
            coge-zumbador;
            apagate;
        fin;
    fin;
    define-nueva-instruccion corre como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            corre;
            deja-zumbador;
        fin
        sino inicio
            avanza;
        fin;
    fin;
    inicia-ejecucion
        mientras no-orientado-al-norte hacer gira-izquierda;
        avanza;
        derecha;
        lugar;
        vuelta;
        avanza;
        si no-junto-a-zumbador entonces inicio
            deja-zumbador;
        fin
        sino inicio
            corre;
            vuelta;
            avanza;
            deja-zumbador;
            vuelta;
        fin;
        mientras frente-libre hacer avanza;
        vuelta;
        si no-junto-a-zumbador entonces avanza;
        colados(0);
        vuelta;
        mientras no-junto-a-zumbador hacer avanza;
        recorre(0);
        si junto-a-zumbador entonces coge-zumbador;
        mientras no-junto-a-zumbador hacer avanza;
        mientras frente-libre hacer avanza;
        derecha;
        avanza;
        derecha;
        mientras no-junto-a-zumbador hacer avanza;
        manda(0);
        apagate;
    termina-ejecucion
finalizar-programa
