iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion gandaya (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            gandaya (sucede(n));
        fin
        sino inicio
            sur;
            avanza;
            este;
            repetir precede (n) veces
                avanza;
            oeste;
        fin;
    fin;
    define-nueva-instruccion sacar (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sacar (sucede(n));
        fin
        sino inicio
            norte;
            avanza;
            repetir n veces
                deja-zumbador;
            sur;
            avanza;
            oeste;
        fin;
    fin;
    define-nueva-instruccion colados (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            colados (sucede(n));
        fin
        sino inicio
            oeste;
            avanza;
            gandaya (0);
            si frente-libre entonces inicio
                avanza;
                repetir n veces inicio
                    sacar (0);
                    si frente-libre entonces
                        avanza;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion tortilla (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            tortilla (sucede(n));
        fin
        sino inicio
            oeste;
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
            este;
            si junto-a-zumbador entonces
                avanza;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion poner (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            poner (sucede(n));
        fin
        sino inicio
            oeste;
            mientras frente-libre hacer
                avanza;
            sur;
            avanza;
            este;
            mientras frente-libre y junto-a-zumbador hacer
                avanza;
            repetir n veces
                deja-zumbador;
            oeste;
            mientras frente-libre hacer
                avanza;
            norte;
            avanza;
            este;
        fin;
    fin;
    inicia-ejecucion
        norte;
        avanza;
        este;
        avanza;
        colados (0);
        este;
        si frente-libre entonces
            avanza;
        mientras frente-libre o junto-a-zumbador hacer inicio
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
            si junto-a-zumbador entonces inicio
                tortilla (0);
                si frente-libre entonces
                    avanza;
            fin;
        fin;
        oeste;
        mientras frente-libre hacer
            avanza;
        norte;
        avanza;
        este;
        mientras frente-libre hacer inicio
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
            si junto-a-zumbador entonces inicio
                poner (0);
            fin
            sino inicio
                oeste;
                mientras frente-libre hacer
                    avanza;
                sur;
                avanza;
                este;
                apagate;
            fin;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa