iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion limpiar como
        inicio
           mientras orientado-al-este hacer
               inicio
                  mientras junto-a-zumbador hacer coge-zumbador;
                  si frente-libre entonces avanza sino
                      inicio
                         oeste;
                         mientras no-junto-a-zumbador hacer avanza;
                      fin;
               fin;
        fin;
    define-nueva-instruccion contar2(g) como
        inicio
           si junto-a-zumbador entonces
               inicio
                  coge-zumbador;
                  contar2(sucede(g));
               fin sino
                   inicio
                      si frente-bloqueado y orientado-al-oeste entonces
                          inicio
                             sur;
                             avanza;
                             este;
                             repetir precede(g) veces avanza;
                             oeste;
                          fin sino
                              inicio
                                 si derecha-bloqueada entonces
                                     inicio
                                        oeste;
                                        mientras frente-libre hacer avanza;
                                        este;
                                        mientras junto-a-zumbador y frente-libre hacer avanza;
                                        repetir g veces deja-zumbador;
                                        si frente-libre entonces avanza;
                                        mientras no-junto-a-zumbador y frente-libre hacer avanza;
                                     fin sino
                                         inicio
                                            sur;
                                            avanza;
                                            este;
                                            mientras junto-a-zumbador y frente-libre hacer avanza;
                                            repetir g veces deja-zumbador;
                                            oeste;
                                            mientras frente-libre hacer avanza;
                                            norte;
                                            avanza;
                                            este;
                                            mientras no-junto-a-zumbador y frente-libre hacer avanza;
                                         fin;
                              fin;
                   fin;
        fin;

    define-nueva-instruccion contar(g) como
        inicio
           si junto-a-zumbador entonces
               inicio
                  coge-zumbador;
                  contar(sucede(g));
               fin sino
                   inicio
                      avanza;
                      contar2(0);
                      si frente-libre entonces avanza;
                      repetir g veces
                          inicio
                             mientras junto-a-zumbador hacer
                                 inicio
                                    coge-zumbador;
                                    norte;
                                    avanza;
                                    deja-zumbador;
                                    sur;
                                    avanza;
                                 fin;
                             oeste;
                             si frente-libre entonces avanza;
                          fin;
                      este;
                      si frente-libre entonces avanza;
                      mientras no-junto-a-zumbador hacer avanza;
                   fin;
        fin;

    inicia-ejecucion
        norte;
        avanza;
        este;
        repetir 2 veces avanza;
        limpiar;
        contar(0);
        mientras junto-a-zumbador hacer contar2(0);
        oeste;
        mientras frente-libre hacer avanza;
        norte;
        avanza;
        este;
        mientras no-junto-a-zumbador hacer avanza;
        mientras junto-a-zumbador hacer contar2(0);
        apagate;
    termina-ejecucion
finalizar-programa
