iniciar-programa
define-nueva-instruccion am(c) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        am (sucede(c));
    fin
    sino inicio
        gira-izquierda;
        avanza;
        repetir c veces deja-zumbador;
        repetir 2 veces gira-izquierda;
        avanza;
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion amigos(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        amigos(sucede(a));
    fin
    sino inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        repetir 3 veces gira-izquierda;
        avanza;
        repetir 3 veces gira-izquierda;
        mientras no-junto-a-zumbador hacer avanza;
        repetir 2 veces gira-izquierda;
        coge-zumbador;
        repetir a veces avanza;
        gira-izquierda;
        repetir 2 veces avanza;
        gira-izquierda;
        repetir a veces inicio
            mientras no-junto-a-zumbador hacer avanza;
            am(0);
        fin;
    fin;
fin;
define-nueva-instruccion lugar(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        lugar (sucede(n));
    fin
    sino inicio
        avanza;
        repetir 3 veces gira-izquierda;
        repetir precede(n) veces avanza;
        deja-zumbador;
        repetir 2 veces gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        avanza;
        gira-izquierda;
        avanza;
        amigos(0);
    fin;
fin;
define-nueva-instruccion ordena(d) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        ordena (sucede(d));
    fin
    sino inicio
        repetir 2 veces gira-izquierda;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si junto-a-zumbador entonces inicio
            repetir 2 veces gira-izquierda;
            avanza;
        fin;
        mientras no-orientado-al-este hacer gira-izquierda;
        repetir d veces deja-zumbador;
        avanza;
    fin;
fin;
define-nueva-instruccion ordena2(h) como inicio
    si frente-bloqueado entonces inicio
        repetir 2 veces gira-izquierda;
        avanza;
        repetir 3 veces gira-izquierda;
        mientras no-junto-a-zumbador y frente-libre hacer avanzA;
        si frente-bloqueado y no-junto-a-zumbador entonces apagate;
    fin;
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        ordena2(sucede(h));
    fin
    sino inicio
        repetir 3 veces gira-izquierda;
        avanza;
        gira-izquierda;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        repetir h veces deja-zumbador;
        repetir 2 veces gira-izquierda;
        mientras frente-libre hacer avanza;
        repetir 3 veces gira-izquierda;
        avanza;
        mientras no-orientado-al-sur hacer gira-izquierda;
        avanza;
    fin;
fin;
    inicia-ejecucion
    mientras no-orientado-al-norte hacer gira-izquierda;
    avanza;
    lugar(0);
    mientras frente-libre hacer inicio
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si frente-bloqueado y no-junto-a-zumbador entonces inicio
            repetir 2 veces gira-izquierda;
            mientras frente-libre hacer avanza;
            repetir 3 veces gira-izquierda;
            avanza;
            repetir 3 veces gira-izquierda;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si frente-bloqueado y no-junto-a-zumbador entonces apagate;
            mientras no-orientado-al-sur hacer gira-izquierda;
            avanza;
            mientras frente-bloqueado hacer ordena2(0);
        fin;

        ordena(0);
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
