iniciar-programa

    define-nueva-instruccion gira-derecha como inicio
        gira-izquierda;
        gira-izquierda;
        gira-izquierda;
    fin;

    define-nueva-instruccion media-vuelta como inicio
        gira-izquierda;
        gira-izquierda;
    fin;

    define-nueva-instruccion orienta como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
        avanza;
        gira-derecha;
        avanza;
    fin;

    define-nueva-instruccion saca como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            saca;
            deja-zumbador;
        fin
        sino inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion quien como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            quien;
            si orientado-al-sur entonces inicio
                gira-izquierda;
            fin
            sino avanza;
        fin
        sino inicio
            gira-izquierda;
            avanza;
        fin;
    fin;

    define-nueva-instruccion cuantos(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuantos(sucede(n));
        fin
        sino inicio
            media-vuelta;
            avanza;
            quien;
            media-vuelta;
            avanza;
            repetir n veces inicio
                mientras no-orientado-al-norte hacer gira-izquierda;
                saca;
                media-vuelta;
                avanza;
                gira-derecha;
                si frente-libre entonces avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion acomoda2 como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            acomoda2;
            deja-zumbador;
        fin
        sino inicio
            media-vuelta;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si junto-a-zumbador entonces inicio
                media-vuelta;
                avanza;
            fin
            sino inicio
                media-vuelta;
            fin;
        fin;
    fin;

    define-nueva-instruccion acomoda3 como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            acomoda3;
            deja-zumbador;
        fin
        sino inicio
            gira-derecha;
            avanza;
            gira-izquierda;
            mientras junto-a-zumbador y frente-libre hacer avanza;
            media-vuelta;
        fin;
    fin;

    define-nueva-instruccion acomoda como inicio
        si junto-a-zumbador entonces inicio
            media-vuelta;
            avanza;
        fin
        sino inicio
            media-vuelta;
        fin;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        mientras junto-a-zumbador hacer inicio
            acomoda2;
            avanza;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
        fin;
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-derecha;
        avanza;
        gira-derecha;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        mientras junto-a-zumbador hacer inicio
            acomoda3;
            mientras frente-libre hacer avanza;
            gira-derecha;
            avanza;
            gira-derecha;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
        fin;
    fin;

    inicia-ejecucion
        orienta;
        cuantos(0);
        acomoda;
        apagate;
    termina-ejecucion
finalizar-programa
