iniciar-programa

define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion orilla como inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        repetir 3 veces deja-zumbador;
    fin;

    define-nueva-instruccion busca como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
            fin sino inicio
                deja-zumbador;
                deja-zumbador;

                norte;
                si frente-libre entonces inicio
                    avanza;
                    norte;
                    busca;
                    si orientado-al-sur entonces inicio
                        sur;
                        avanza;
                        orilla;
                    fin sino inicio
                        sur;
                        avanza;
                    fin;

                fin sino inicio
                    orilla;
                fin;

                sur;
                si frente-libre entonces inicio
                    avanza;
                    norte;
                    busca;
                    si orientado-al-sur entonces inicio
                        norte;
                        avanza;
                        orilla;
                    fin sino inicio
                        norte;
                        avanza;
                    fin;

                fin sino inicio
                    orilla;
                fin;

                este;
                si frente-libre entonces inicio
                    avanza;
                    norte;
                    busca;
                    si orientado-al-sur entonces inicio
                        oeste;
                        avanza;
                        orilla;
                    fin sino inicio
                        oeste;
                        avanza;
                    fin;

                fin sino inicio
                    orilla;
                fin;

                oeste;
                si frente-libre entonces inicio
                    avanza;
                    norte;
                    busca;
                    si orientado-al-sur entonces inicio
                        este;
                        avanza;
                        orilla;
                    fin sino inicio
                        este;
                        avanza;
                    fin;

                fin sino inicio
                    orilla;
                fin;

            fin;
        fin sino inicio
            sur;
        fin;
    fin;

    define-nueva-instruccion busca2 como inicio
        si junto-a-zumbador entonces inicio

            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
            fin sino inicio
                coge-zumbador;


                norte;
                si frente-libre entonces inicio
                    avanza;
                    busca2;
                    sur;
                    avanza;
                fin;

                este;
                si frente-libre entonces inicio
                    avanza;
                    busca2;
                    oeste;
                    avanza;
                fin;

                oeste;
                si frente-libre entonces inicio
                    avanza;
                    busca2;
                    este;
                    avanza;
                fin;

                sur;
                si frente-libre entonces inicio
                    avanza;
                    busca2;
                    norte;
                    avanza;
                fin;

            fin;

        fin;


    fin;


    inicia-ejecucion

        busca;
        busca2;

        apagate;
    termina-ejecucion
finalizar-programa
