iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira(1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira(1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira(1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira(1);
    fin;
    define-nueva-instruccion quitarzumbadores como inicio
        si junto-a-zumbador  entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                norte;
                si frente-libre entonces inicio
                    avanza;
                    si junto-a-zumbador entonces
                        quitarzumbadores;
                    sur;
                    si frente-libre entonces
                        avanza;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    si junto-a-zumbador entonces
                        quitarzumbadores;
                    oeste;
                    si frente-libre entonces
                        avanza;
                fin;
                sur;
                si frente-libre entonces inicio
                    avanza;
                    si junto-a-zumbador entonces
                        quitarzumbadores;
                    norte;
                    si frente-libre entonces
                        avanza;
                fin;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    si junto-a-zumbador entonces
                        quitarzumbadores;
                    este;
                    si frente-libre entonces
                        avanza;
                fin;
            fin
            sino inicio
                deja-zumbador;
            fin;

        fin
    fin;
    define-nueva-instruccion orillar como inicio
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                gira(2);
                si frente-libre entonces
                    avanza;
                mientras junto-a-zumbador hacer
                    coge-zumbador;
                repetir 3 veces
                    deja-zumbador;
            fin
            sino inicio
                gira(2);
                si frente-libre entonces
                    avanza;
            fin;
        fin
        sino inicio
            si frente-bloqueado entonces inicio
                mientras junto-a-zumbador hacer
                    coge-zumbador;
                repetir 3 veces
                    deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion busqueda como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
            fin
            sino inicio
                repetir 2 veces
                    deja-zumbador;
                norte;
                orillar;
                este;
                orillar;
                sur;
                orillar;
                oeste;
                orillar;
                norte;
                si frente-libre entonces inicio
                   avanza;
                   si junto-a-zumbador entonces
                       busqueda;
                   sur;
                   si frente-libre entonces
                       avanza;
                fin;
                este;
                si frente-libre entonces inicio
                   avanza;
                   si junto-a-zumbador entonces
                       busqueda;
                   oeste;
                   si frente-libre entonces
                       avanza;
                fin;
                sur;
                si frente-libre entonces inicio
                   avanza;
                   si junto-a-zumbador entonces
                       busqueda;
                   norte;
                   si frente-libre entonces
                       avanza;
                fin;
                oeste;
                si frente-libre entonces inicio
                   avanza;
                   si junto-a-zumbador entonces
                       busqueda;
                   este;
                   si frente-libre entonces
                       avanza;
                fin;
            fin;
        fin
    fin;
    inicia-ejecucion
        busqueda;
        quitarzumbadores;
        apagate;
    termina-ejecucion
finalizar-programa
