iniciar-programa
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion avanzar como mientras frente-libre hacer avanza;
    define-nueva-instruccion orilla como  inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                repetir 2 veces deja-zumbador;
                norte;
                si frente-libre entonces inicio
                    avanza;
                    orilla;
                    sur;
                    si frente-libre entonces avanza;
                fin;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    orilla;
                    este;
                    si frente-libre entonces avanza;
                fin;
                sur;
                si frente-libre entonces inicio
                    avanza;
                    orilla;
                    norte;
                    si frente-libre entonces avanza;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    orilla;
                    oeste;
                    si frente-libre entonces avanza;
                fin;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio
            repetir 3 veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion busca3 como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    repetir 2 veces gira-izquierda;
                    avanza;
                    mientras junto-a-zumbador hacer coge-zumbador;
                    deja-zumbador;
                    repetir 2 veces gira-izquierda;
                    avanza;
                    repetir 3 veces deja-zumbador;
                fin sino inicio
                    norte;
                    si frente-libre entonces inicio
                        avanza;
                        busca3;
                        sur;
                        si frente-libre entonces avanza;
                    fin sino inicio
                        mientras junto-a-zumbador hacer coge-zumbador;
                        deja-zumbador;
                    fin;
                    oeste;
                    si frente-libre entonces inicio
                        avanza;
                        busca3;
                        este;
                        si frente-libre entonces avanza;
                    fin sino inicio
                        mientras junto-a-zumbador hacer coge-zumbador;
                        deja-zumbador;
                    fin;
                    sur;
                    si frente-libre entonces inicio
                        avanza;
                        busca3;
                        norte;
                        si frente-libre entonces avanza;
                    fin sino inicio
                        mientras junto-a-zumbador hacer coge-zumbador;
                        deja-zumbador;
                    fin;
                    este;
                    si frente-libre entonces inicio
                        avanza;
                        busca3;
                        oeste;
                        si frente-libre entonces avanza;
                    fin sino inicio
                        mientras junto-a-zumbador hacer coge-zumbador;
                        deja-zumbador;
                    fin;
                fin
            fin sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion cambia como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            si orientado-al-norte entonces  inicio
                este;
                si frente-libre entonces inicio
                    avanza;
                    sur;
                fin sino inicio
                    oeste;
                fin;
            fin sino inicio
                este;
                si frente-libre entonces inicio
                    avanza;
                    norte;
                fin sino inicio
                    oeste;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion quita como inicio
        oeste;
        avanzar;
        sur;
        avanzar;
        norte;
        mientras no-orientado-al-oeste hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    coge-zumbador;
                    cambia;
                fin sino inicio
                    deja-zumbador;
                    cambia;
                fin;
            fin sino inicio
                cambia;
            fin;
        fin;
    fin;
    inicia-ejecucion
        orilla;
        busca3;
        quita;
        apagate;
    termina-ejecucion
finalizar-programa
