iniciar-programa
    define-nueva-instruccion norte como  mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

     define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer  inicio
        avanza;
        fin;
        oeste;
        mientras frente-libre hacer  inicio
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion tomar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            tomar(sucede(n));
        fin sino inicio
            si si-es-cero(precede(precede(precede(precede(n))))) entonces inicio
                repetir 4 veces inicio
                    deja-zumbador;
                fin;
            fin sino inicio
                repetir 2 veces inicio
                    deja-zumbador;
                fin
            fin;
        fin;
    fin;

    define-nueva-instruccion relleno como inicio
        norte;
        repetir 4 veces inicio
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    gira-izquierda;
                    gira-izquierda;
                    avanza;
                    deja-zumbador;
                    gira-izquierdA;
                fin sino inicio
                    gira-izquierda;
                    gira-izquierda;
                    avanza;
                    gira-izquierda;
                fin;
            fin sino inicio
                gira-izquierda;
                gira-izquierda;
                gira-izquierda;
            fin;
        fin;
        tomar(0);
    fin;

    define-nueva-instruccion buscar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            buscar(sucede(n));
        fin sino inicio
            si si-es-cero(precede(n)) entonces inicio
                relleno;
                norte;
                si frente-libre entonces  inicio
                    avanza;
                    buscar(0);
                    sur;
                    avanza;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    buscar(0);
                    oeste;
                    avanza;
                fin;
                sur;
                si frente-libre entonces  inicio
                    avanza;
                    buscar(0);
                    norte;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces  inicio
                    avanza;
                    buscar(0);
                    este;
                    avanza;
                fin;
            fin sino inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion quitar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            quitar(sucede(n));
        fin sino inicio
            si si-es-cero(precede(precede(n))) o si-es-cero(precede(n)) entonces inicio
                deja-zumbador;
            fin;
            si frente-libre entonces inicio
                avanza;
                quitar(0);
            fin;
            si frente-bloqueado y izquierda-libre entonces inicio
                norte;
                avanza;
                oeste;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                este;
                quitar(0);
            fin;
        fin;
    fin;

    inicia-ejecucion
        buscar(0);
        ir11;
        quitar(0);
        apagate;
    termina-ejecucion
finalizar-programa
