iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierdA;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierdA;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierdA;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierdA;
    define-nueva-instruccion revisar como inicio
        repetir 4 veces inicio
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    gira-izquierda;
                    gira-izquierda;
                    avanza;
                    deja-zumbador;
                    gira-izquierda;
                fin sino inicio
                    gira-izquierda;
                    gira-izquierda;
                    avanza;
                    gira-izquierda;
                fin;
            fin sino inicio
                gira-izquierda;
                gira-izquierda;
                gira-izquierda;
            fin;
        fin;
    fin;
    define-nueva-instruccion busqueda como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                revisar;
                norte;
                si frente-libre entonces inicio
                    avanza;
                    busqueda;
                    sur;
                    avanza;
                fin;
                sur;
                si frente-libre entonces inicio
                    avanza;
                    busqueda;
                    norte;
                    avanza;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    busqueda;
                    oeste;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    busqueda;
                    este;
                    avanza;
                fin;
            fin sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion ir11 como inicio
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
    fin;
    define-nueva-instruccion compara(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara(sucede(n));
        fin sino inicio
            si no si-es-cero (precede(precede(precede(precede(n))))) entonces inicio
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion avanzar como inicio
         si frente-bloqueado entonces inicio
              oeste;
              mientras frente-libre hacer inicio
                 avanza;
              fin;
              norte;
              avanza;
              este;
          fin sino inicio
              avanza;
          fin;
    fin;
    define-nueva-instruccion limpiar como inicio
        mientras izquierda-libre o frente-libre  hacer inicio
            si junto-a-zumbador entonces inicio
                compara(0);
                avanzar;
            fin sino inicio
                avanzar;
            fin;
        fin;
        si frente-bloqueado y izquierda-bloqueada y junto-a-zumbador entonces inicio
            compara(0);
        fin;
    fin;
    inicia-ejecucion
        norte;
        busqueda;
        ir11;
        limpiar;
        apagate;
    termina-ejecucion
finalizar-programa
