iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion checa como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                sur;
                avanza;
                deja-zumbador;
                deja-zumbador;
            fin
            sino inicio
                sur;
                avanza;
                este;
                si frente-libre entonces inicio
                    avanza;
                    si no-junto-a-zumbador entonces inicio
                        oeste;
                        avanza;
                        deja-zumbador;
                        deja-zumbador;
                    fin
                    sino inicio
                        oeste;
                        avanza;
                        sur;
                        si frente-libre entonces inicio
                            avanza;
                            si no-junto-a-zumbador entonces inicio
                                norte;
                                avanza;
                                deja-zumbador;
                                deja-zumbador;
                            fin
                            sino inicio
                                norte;
                                avanza;
                                oeste;
                                si frente-libre entonces inicio
                                    avanza;
                                    si no-junto-a-zumbador entonces inicio
                                        este;
                                        avanza;
                                        deja-zumbador;
                                        deja-zumbador;
                                    fin
                                    sino inicio
                                        este;
                                        avanza;
                                        deja-zumbador;
                                    fin;
                                fin
                                sino inicio
                                    deja-zumbador;
                                    deja-zumbador;
                                fin;
                            fin;
                        fin
                        sino inicio
                            deja-zumbador;
                            deja-zumbador;
                        fin;
                    fin;
                fin
                sino inicio
                    deja-zumbador;
                    deja-zumbador;
                fin;
            fin;
        fin
        sino inicio
            deja-zumbador;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion busca como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
                checa;
               norte;
               si frente-libre entonces inicio
                   avanza;
                   busca;
                   sur;
                   avanza;
               fin;
               este;
               si frente-libre entonces inicio
                   avanza;
                   busca;
                   oeste;
                   avanza;
               fin;
               sur;
               si frente-libre entonces inicio
                   avanza;
                   busca;
                   norte;
                   avanza;
               fin;
               oeste;
               si frente-libre entonces inicio
                   avanza;
                   busca;
                   este;
                   avanza;
               fin;
            fin
            sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion pastel como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                norte;
                si frente-libre entonces inicio
                    avanza;
                    pastel;
                    sur;
                    avanza;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    pastel;
                    oeste;
                    avanza;
                fin;
                sur;
                si frente-libre entonces inicio
                    avanza;
                    pastel;
                    norte;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    pastel;
                    este;
                    avanza;
                fin;
            fin
            sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;
    inicia-ejecucion
        busca;
        pastel;
        apagate;
    termina-ejecucion
finalizar-programa