iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion media-vuelta como repetir 2 veces gira-izquierda;
    define-nueva-instruccion gira-derecha como repetir 3 veces gira-izquierda;

    define-nueva-instruccion ir11 como inicio
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion avanzar como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            norte;
            avanza;
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            este;
        fin;
    fin;

    define-nueva-instruccion regresa como inicio
        media-vuelta;
        avanza;
    fin;

    define-nueva-instruccion pasar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            pasar(sucede(n));
            deja-zumbador;
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
            regresa;
        fin;
    fin;

    define-nueva-instruccion comparar(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            coge-zumbador;
            comparar(precede(n));
        fin sino inicio
            regresa;
            pasar(0);
            si no si-es-cero(n) entonces inicio
                repetir n veces inicio
                    coge-zumbador;
                fin;
            fin sino inicio
                regresa;
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion pasar2(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            pasar2(sucede(n));
            deja-zumbador;
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
            regresa;
            gira-izquierda;
            avanza;
        fin;
    fin;

    define-nueva-instruccion comparar2(n) como inicio
        si no si-es-cero(n) y junto-a-zumbador entonces inicio
            coge-zumbador;
            comparar2(precede(n));
        fin sino inicio
            regresa;
            gira-derecha;
            avanza;
            pasar2(0);
            si si-es-cero(n) entonces inicio
                regresa;
                gira-derecha;
                avanza;
                oeste;
            fin sino inicio
                repetir n veces inicio
                    coge-zumbador;
                fin;
                regresa;
                gira-derecha;
                avanza;
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion cima(n) como inicio
        repetir 4 veces inicio
            si no junto-a-zumbador entonces inicio
                gira-izquierda;
                si frente-libre entonces inicio
                    repetir n veces inicio
                        deja-zumbador;
                    fin;
                    avanza;
                    comparar(n);
                    si junto-a-zumbador entonces inicio
                        gira-izquierda;
                        si frente-libre entonces inicio
                            avanza;
                            comparar2(n);
                        fin sino inicio
                            gira-izquierda;
                            avanza;
                            mientras junto-a-zumbador hacer inicio
                                coge-zumbador;
                            fin;
                        fin;
                    fin sino inicio
                        oeste;
                        repetir n veces inicio
                            deja-zumbador;
                        fin;
                    fin;
                fin sino inicio
                    media-vuelta;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion checa-cima(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            checa-cima(sucede(n));
        fin sino inicio
            cima(n);
            si no junto-a-zumbador entonces inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion vigias(n) como inicio
        si frente-libre o izquierda-libre entonces inicio
            checa-cima(0);
            si orientado-al-este entonces inicio
                avanzar;
                vigias(sucede(n));
            fin sino inicio
                este;
                avanzar;
                vigias(n);
            fin;
        fin sino inicio
            checa-cima(0);
            si orientado-al-este entonces inicio
                ir11;
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                fin;
                deja-zumbador;
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin sino inicio
                ir11;
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                fin;
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        ir11;
        vigias(0);
        apagate;
    termina-ejecucion
finalizar-programa
