iniciar-programa
    define-nueva-instruccion norte como inicio
       mientras no-orientado-al-norte hacer inicio
          gira-izquierda;
       fin;
    fin;

    define-nueva-instruccion sur como inicio
       mientras no-orientado-al-sur hacer inicio
          gira-izquierda;
       fin;
    fin;

    define-nueva-instruccion este como inicio
       mientras no-orientado-al-este hacer inicio
          gira-izquierda;
       fin;
    fin;

    define-nueva-instruccion oeste como inicio
       mientras no-orientado-al-oeste hacer inicio
          gira-izquierda;
       fin;
    fin;

    define-nueva-instruccion despacha(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            despacha(sucede(n));
        fin sino inicio
            norte;
            si frente-libre entonces inicio
                avanza;
            fin;
            repetir n veces inicio
                deja-zumbador ;
            fin;
            si frente-libre entonces inicio
                avanza;
            fin;
            repetir n veces inicio
                si algun-zumbador-en-la-mochila entonces inicio
                    deja-zumbador;
                fin;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
            fin;
            si frente-libre entonces inicio
                avanza;
            fin;
            si frente-bloqueado y junto-a-zumbador entonces inicio
                apagate;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
            fin;
            si no junto-a-zumbador y algun-zumbador-en-la-mochila entonces inicio
                oeste;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                norte;
                repetir 3 veces inicio
                    si frente-libre entonces inicio
                        avanza;
                    fin;
                fin;
                mientras algun-zumbador-en-la-mochila hacer inicio
                    deja-zumbador;
                fin;
                sur;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                sal-de-instruccion;
            fin;
            si junto-a-zumbador y algun-zumbador-en-la-mochila entonces inicio
                despacha(0);
            fin;
        fin;
    fin;

    define-nueva-instruccion coge(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            coge(sucede(n));
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
            fin;
            repetir n veces inicio
                coge-zumbador;
            fin;
            si no junto-a-zumbador entonces inicio
                mientras algun-zumbador-en-la-mochila hacer inicio
                    deja-zumbador;
                fin;
            fin sino inicio
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                fin;
                sur;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                mientras algun-zumbador-en-la-mochila hacer inicio
                    deja-zumbador
                fin;
                repetir n veces inicio
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                    fin;
                fin;
                norte;
                repetir 2 veces inicio
                    si frente-libre entonces inicio
                        avanza;
                    fin;
                fin;
                repetir n veces inicio
                    si algun-zumbador-en-la-mochila entonces inicio
                        deja-zumbador;
                    fin;
                fin;
                sur;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion regresa como inicio
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        norte;
        repetir 2 veces inicio
            si frente-libre entonces inicio
                avanza;
            fin;
        fin;
        este;
        mientras junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        si no junto-a-zumbador entonces inicio
            oeste;
            si frente-libre entonces inicio
                avanza;
            fin;
        fin;
        coge(0);
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        oeste;
        mientras frente-libre hacer inicio
             avanza;
        fin;
        este;
        mientras no junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion forma(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            forma(sucede(n));
        fin sino inicio
           oeste;
           mientras frente-libre hacer inicio
               avanza;
           fin;
           si junto-a-zumbador entonces inicio
               este;
               mientras junto-a-zumbador y frente-libre hacer inicio
                   avanza;
               fin;
           fin;
           repetir n veces inicio
               deja-zumbador;
           fin;
           este;
           si frente-bloqueado y junto-a-zumbador y ningun-zumbador-en-la-mochila entonces inicio
               apagate;
           fin;
           si frente-libre entonces inicio
               avanza;
           fin;
           mientras no junto-a-zumbador y frente-libre hacer inicio
               avanza;
               si frente-bloqueado y no junto-a-zumbador entonces inicio
                   oeste;
                   mientras frente-libre hacer inicio
                       avanza;
                   fin;
                   apagate;
               fin;
           fin;
           si frente-bloqueado y junto-a-zumbador y ningun-zumbador-en-la-mochila entonces inicio
               mientras junto-a-zumbador hacer inicio
                   coge-zumbador;
               fin;
               oeste;
               mientras frente-libre hacer inicio
                   avanza;
               fin;
               si junto-a-zumbador entonces inicio
                   este;
                   mientras junto-a-zumbador y frente-libre hacer inicio
                       avanza;
                   fin;
               fin;
               mientras algun-zumbador-en-la-mochila hacer inicio
                   deja-zumbador;
               fin;    
               apagate;
           fin;
           si junto-a-zumbador entonces inicio
               forma(0);
           fin;
       fin;
    fin;
    inicia-ejecucion
        despacha(0);
        regresa;
        forma(0);
        apagate;
    termina-ejecucion
finalizar-programa
