iniciar-programa
define-nueva-instruccion gira(N) como repetir n veces gira-izquierda;
define-nueva-instruccion fila como
inicio
    mientras no-junto-a-zumbador y frente-libre hacer avanza;
    si junto-a-zumbador entonces
    inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        gira(2);
        mientras frente-libre hacer avanza;
        gira(2);
        mientras junto-a-zumbador hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        si frente-libre entonces avanza;
        fila;
    fin;
fin;
define-nueva-instruccion busca como
inicio
    mientras frente-libre y no-junto-a-zumbador hacer avanza;
    si frente-bloqueado entonces
    inicio
        gira(2);
        mientras frente-libre hacer avanza;
        deja-zumbador;
        apagate;
    fin
    sino si junto-a-zumbador entonces
    inicio
        deja-zumbador;
        mientras no-orientado-al-oeste hacer gira(1);
        mientras frente-libre hacer avanza;
        gira(3);
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        gira(2);
        avanza;
        gira(1);
        si no-junto-a-zumbador entonces fila sino apagate;
    fin;
fin;
define-nueva-instruccion checa como
inicio
    mientras no-orientado-al-oeste hacer gira-izquierda;
    mientras frente-libre hacer avanza;
    gira(3);
    avanza;
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        gira(2);
        avanza;
        gira(3);
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
    fin
    sino
    inicio
        gira(2);
        avanza;
        gira(1);
        busca;
    fin;
fin;
define-nueva-instruccion tortilla como
si junto-a-zumbador entonces
inicio
    coge-zumbador;
    checa;
    tortilla;
fin
sino
inicio
    mientras no-orientado-al-este hacer gira(1);
    mientras no-junto-a-zumbador y frente-libre hacer avanza;
    si junto-a-zumbador entonces tortilla;
fin;
    inicia-ejecucion
    gira(1);

    avanza;
    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
    gira(2);
    avanza;
    gira(1);
    tortilla;
        apagate;
    termina-ejecucion
finalizar-programa
