iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion cuenta(n) como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            deja-zumbador;
            cuenta(sucede(n))
        fin
        sino inicio
            gira(2);
            avanza;
            gira(1);
            repetir n veces inicio
                si junto-a-zumbador entonces coge-zumbador;
                si no-junto-a-zumbador entonces
                   si frente-libre entonces avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion lleva como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            lleva;
            deja-zumbador;
        fin
        sino inicio
            si frente-libre entonces avanza;
            si junto-a-zumbador entonces lleva
            sino inicio
                mientras frente-libre hacer avanza;
                gira(2);
            fin;
            si junto-a-zumbador entonces avanza;
        fin;
    fin;

    inicia-ejecucion
        mientras no-orientado-al-norte hacer gira(1);
        avanza;
        cuenta(0);
        mientras junto-a-zumbador y frente-libre hacer avanza;
        gira(2);
        si no-junto-a-zumbador entonces avanza;
        lleva;
        apagate;
    termina-ejecucion
finalizar-programa
