iniciar-programa

    define-nueva-instruccion norte como
        mientras no-orientado-al-norte hacer
            gira-izquierda;

    define-nueva-instruccion este como
        mientras no-orientado-al-este hacer
            gira-izquierda;

    define-nueva-instruccion oeste como
        mientras no-orientado-al-oeste hacer
            gira-izquierda;

    define-nueva-instruccion sur como
        mientras no-orientado-al-sur hacer
            gira-izquierda;

    define-nueva-instruccion meterse como inicio
        norte;
        avanza;
    fin;

    define-nueva-instruccion ajusta como inicio
        si orientado-al-norte entonces inicio
            este;
            si frente-libre entonces inicio
                avanza;
                sur;
            fin;
        fin
        sino inicio
            este;
            si frente-libre entonces inicio
                avanza;
                norte;
            fin;
        fin;
    fin;

    define-nueva-instruccion Ir11 como inicio
        oeste;
        mientras frente-libre hacer
            avanza;
        sur;
        mientras frente-libre hacer
            avanza;
        este;
    fin;

    define-nueva-instruccion camina (n) como
        repetir n veces
            avanza;

    define-nueva-instruccion determina_pareja como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
        fin
        sino inicio
            deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion siguiente-zumbador como inicio
        mientras no-orientado-al-este y no-junto-a-zumbador hacer inicio
            si frente-libre entonces inicio
                avanza;
            fin
            sino inicio
                ajusta;
                si frente-bloqueado y no orientado-al-sur y no orientado-al-norte entonces
                    este;
            fin;
        fin;
    fin;

    define-nueva-instruccion ordenar (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ordenar (sucede (n));
        fin
        sino inicio
            si no-orientado-al-este entonces inicio
                siguiente-zumbador;
                ordenar (0);
            fin;
            si no si-es-cero (n) entonces inicio
                Ir11;
                camina (precede (n));
                determina_pareja;
            fin;
        fin;
    fin;

    define-nueva-instruccion tirar-zumbadores como inicio
        Ir11;
        norte;
        avanza;
        mientras algun-zumbador-en-la-mochila hacer
            deja-zumbador;
    fin;

    define-nueva-instruccion impar como inicio
        Ir11;
        mientras frente-libre hacer inicio
            avanza;
            si junto-a-zumbador entonces
                coge-zumbador;
        fin;
        Ir11;
        mientras algun-zumbador-en-la-mochila hacer
            deja-zumbador;
    fin;

    inicia-ejecucion
        meterse;
        ordenar (0);
        tirar-zumbadores;
        impar;
        apagate;
    termina-ejecucion                                           
finalizar-programa
