iniciar-programa
define-nueva-instruccion gira-derecha como
inicio
    gira-izquierda;
    gira-izquierda;
    gira-izquierda;
fin;
define-nueva-instruccion media-vuelta como
inicio
    gira-izquierda;
    gira-izquierda;
fin;
define-nueva-instruccion calcetines como
inicio
    mientras no-orientado-al-oeste hacer gira-izquierda;
    mientras frente-libre hacer avanza;
    gira-izquierda;
    mientras frente-libre hacer avanza;
    gira-izquierda;
    mientras frente-libre hacer avanza;
    media-vuelta;
    mientras frente-libre hacer
    inicio
        si junto-a-zumbador entonces coge-zumbador;
        avanza;
    fin;
    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
fin;
define-nueva-instruccion busca como
inicio
    mientras no-junto-a-zumbador hacer
    inicio
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si no-junto-a-zumbador entonces
        inicio
            gira-derecha;
            si frente-libre entonces
            inicio
                avanza;
                gira-derecha;
                mientras frente-libre hacer avanza;
                media-vuelta;
            fin
            sino inicio
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                calcetines;
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion par(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        par(sucede(n));
    fin
    sino inicio
        media-vuelta;
        mientras frente-libre hacer avanza;
        gira-derecha;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        repetir n veces avanza;
        deja-zumbador;
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si junto-a-zumbador entonces
            inicio
                mientras junto-a-zumbador hacer coge-zumbador;
            fin
            sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;
fin;
    inicia-ejecucion
        mientras no-orientado-al-norte hacer gira-izquierda;
        mientras frente-libre hacer
        inicio
            avanza;
            busca;
            si no-orientado-al-oeste entonces
            inicio
                par(0);
                media-vuelta;
                mientras frente-libre hacer avanza;
                gira-derecha;
            fin;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa