iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda; 
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda; 
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda; 

    define-nueva-instruccion ir11 como inicio
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este
    fin;

    define-nueva-instruccion formar(n) como inicio
        repetir n veces inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion buscar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            buscar(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                buscar(0);
            fin sino inicio
                si frente-bloqueado y izquierda-libre entonces inicio
                    norte;
                    avanza;
                    oeste;
                    mientras frente-libre hacer inicio
                        avanzA;
                    fin;
                    este;
                    buscar(0);
                fin;
            fin;
            si no si-es-cero(n) entonces inicio
                ir11;
                formar(precede(n));
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion revisar como inicio
        mientras frente-libre y no junto-a-zumbador hacer inicio
            avanza;
        fin;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                fin;
            fin sino inicio
                ir11;
                deja-zumbador;
                avanza;
            fin;
        fin;
    fin;

    inicia-ejecucion
        norte;
        avanza;
        este;
        buscar(0);
        ir11;
        mientras orientado-al-este y frente-libre hacer inicio
            revisar;
        fin;
        ir11;
        apagate;
    termina-ejecucion
finalizar-programa
 