iniciar-programa
define-nueva-instruccion gira-derecha como
inicio
    repetir 3 veces
       gira-izquierda;
fin;
define-nueva-instruccion mira-norte como
inicio
    mientras no-orientado-al-norte hacer
       gira-izquierda;
fin;
define-nueva-instruccion mira-este como
inicio
   mientras no-orientado-al-este hacer
      gira-izquierda;
fin;
define-nueva-instruccion mira-oeste como
inicio
   mientras no-orientado-al-oeste hacer
       gira-izquierda;
fin;
define-nueva-instruccion mira-sur como
inicio
   mientras no-orientado-al-sur hacer
      gira-izquierda;
fin;
define-nueva-instruccion paso-atras como
inicio
    repetir 2 veces
       gira-izquierda;
    avanza;
    repetir 2 veces
       gira-izquierda;
fin;
define-nueva-instruccion ubicate como
inicio
    mira-oeste;
    mientras frente-libre hacer
      avanza;
    mira-sur;
    mientras frente-libre hacer
      avanza;
fin;
define-nueva-instruccion pregunta(n) como
inicio
   repetir n veces
   inicio
      si junto-a-zumbador entonces
      inicio
         coge-zumbador;
      fin
      sino
         mira-este;
   fin;
fin;
define-nueva-instruccion regresa como
inicio
   ubicate;
   gira-izquierda;
   avanza;
   mientras algun-zumbador-en-la-mochila hacer
      deja-zumbador;
   paso-atras;
   mira-norte;
   avanza;
fin;
define-nueva-instruccion nopareja como
inicio
   ubicate;
   deja-zumbador;
   gira-izquierda;
   avanza;
   mientras algun-zumbador-en-la-mochila hacer
      deja-zumbador;
   paso-atras;
   mira-norte;
   avanza;
fin;
define-nueva-instruccion encuentra(n) como
inicio
   mientras derecha-libre hacer
   inicio
      si junto-a-zumbador entonces
      inicio
          pregunta(n);
          si junto-a-zumbador entonces
          inicio
              repetir n veces
                 deja-zumbador;
          fin
          sino
          inicio
              si orientado-al-norte entonces
              inicio
                  regresa;
                  sal-de-instruccion;
              fin
              sino
              inicio
                  mientras algun-zumbador-en-la-mochila hacer
                      deja-zumbador;
                  repetir n veces
                     coge-zumbador;
              fin;
          fin;
          mira-norte;
      fin;
      si frente-libre entonces
      inicio
         avanza;
      fin
      sino
      inicio
         gira-derecha;
         avanza;
         gira-derecha;
         mientras frente-libre hacer
            avanza;
         mira-norte;
      fin;
   fin;
   (*Hacer la ultima fila*)
   mientras frente-libre hacer
   inicio
       si junto-a-zumbador entonces
       inicio
           pregunta(n);
           si junto-a-zumbador entonces
           inicio
               repetir n veces
                  deja-zumbador;
           fin
           sino
           inicio
               si orientado-al-este entonces
               inicio
                  mientras algun-zumbador-en-la-mochila hacer
                     deja-zumbador;
                  repetir n veces
                     coge-zumbador;
               fin
               sino
               inicio
                   regresa;
                   sal-de-instruccion;
               fin;
           fin;
           mira-norte;
       fin;
       avanza;
   fin;
   (*la ultima casilla*)
   si junto-a-zumbador entonces
   inicio
       pregunta(n);
       si junto-a-zumbador entonces
       inicio
           repetir n veces
              deja-zumbador;
       fin
       sino
       inicio
          si orientado-al-este entonces
          inicio
              mientras algun-zumbador-en-la-mochila hacer
                 deja-zumbador;
              repetir n veces
                  coge-zumbador;
          fin
          sino
          inicio
              regresa;
              sal-de-instruccion;
          fin;
       fin;
       mira-norte;
   fin;
   nopareja;
fin;
define-nueva-instruccion cuenta(n) como
inicio
   si junto-a-zumbador entonces
   inicio
      coge-zumbador;
      cuenta(sucede(n));
   fin
   sino
   inicio
       encuentra(n);
   fin;
fin;
define-nueva-instruccion busca como
inicio
    mientras derecha-libre hacer
    inicio
       si junto-a-zumbador entonces
       inicio
           cuenta(0);
       fin;
       si frente-libre entonces
       inicio
           avanza;
       fin
       sino
       inicio
          gira-derecha;
          avanza;
          gira-derecha;
          mientras frente-libre hacer
             avanza;
          mira-norte;
       fin;
    fin;
    mientras frente-libre hacer
    inicio
        si junto-a-zumbador entonces
        inicio
            cuenta(0);
            mira-este;
            mientras frente-libre hacer
               avanza;
            mira-norte;
        fin;
        avanza;
    fin;
    mira-este;
    mientras frente-libre hacer
      avanza;
    mira-norte;
    mientras frente-libre hacer
      avanza;
    si junto-a-zumbador entonces
    inicio
        cuenta(0);
    fin;
fin;
    inicia-ejecucion
        mira-norte;
        avanza;
        busca;
        apagate;
    termina-ejecucion
finalizar-programa
