iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion baja como
        inicio
            oeste;
            mientras frente-libre hacer avanza;
            sur;
            mientras frente-libre hacer avanza;
            este;
        fin;

    define-nueva-instruccion sube como
        inicio
            oeste;
            mientras frente-libre hacer avanza;
            norte;
            si frente-libre entonces avanza;
        fin;

    define-nueva-instruccion subir como
        inicio
            este;
            mientras frente-libre hacer avanza;
            oeste;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si frente-bloqueado y no-junto-a-zumbador entonces
                inicio
                    norte;
                fin;
        fin;

    define-nueva-instruccion recoge como
        inicio
            si junto-a-zumbador entonces
                inicio
                    coge-zumbador;
                    si no-junto-a-zumbador entonces baja;
                    recoge;
                    avanza;
                fin;
        fin;

     define-nueva-instruccion vaciar como
         inicio
             avanza;
             mientras izquierda-bloqueada hacer avanza;
             norte;
             avanza;
             mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
             sur;
             avanza;
             oeste;
             mientras frente-libre hacer avanza;
             este;
         fin;

    define-nueva-instruccion sin-par como
        inicio
            este;
            mientras frente-libre hacer avanza;
            oeste;
            mientras no-junto-a-zumbador hacer avanza;
            mientras junto-a-zumbador hacer
                inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces
                        inicio
                            deja-zumbador;
                            avanza;
                        fin;
                    mientras frente-libre y no-junto-a-zumbador hacer avanza;
                fin;
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        fin;

    inicia-ejecucion
        norte;
        mientras no-orientado-al-sur hacer
            inicio
                si orientado-al-norte y frente-bloqueado entonces
                    inicio
                        baja;
                        vaciar;
                        sin-par;
                        apagate;
                    fin;
                sube;
                subir;
                si junto-a-zumbador entonces
                    inicio
                        recoge;
                        deja-zumbador;
                    fin;
            fin;
        apagate;
    termina-ejecucion
finalizar-programa
