iniciar-programa
    define-nueva-instruccion norte como inicio
       mientras no-orientado-al-norte hacer inicio
          gira-izquierda;
       fin;
    fin;

    define-nueva-instruccion sur como inicio
       mientras no-orientado-al-sur hacer inicio
          gira-izquierda;
       fin;
    fin;

    define-nueva-instruccion este como inicio
       mientras no-orientado-al-este hacer inicio
          gira-izquierda;
       fin;
    fin;

    define-nueva-instruccion oeste como inicio
       mientras no-orientado-al-oeste hacer inicio
          gira-izquierda;
       fin;
    fin;

    define-nueva-instruccion ubicate1 como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion calcetin(n) como inicio
        este;
        repetir n veces inicio
            avanza;
        fin;
        repetir n veces inicio
            deja-zumbador;
        fin;
        si junto-a-zumbador entonces inicio
            repetir precede(n) veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin;
            fin;
        fin;
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion junta(n) como inicio
        si junto-a-zumbador y no orientado-al-oeste entonces inicio
            coge-zumbador;
            junta(sucede(n));
        fin sino inicio
            si frente-libre y no orientado-al-oeste entonces inicio
                avanza;
                junta(0);
            fin sino inicio
                este;
                si frente-libre entonces inicio
                    avanza;
                    si derecha-bloqueada y izquierda-bloqueada entonces inicio
                        repetir 4 veces inicio
                            gira-izquierda;
                        fin;
                    fin;
                    si derecha-bloqueada y izquierda-libre entonces inicio
                        norte;
                    fin;
                    si izquierda-bloqueada y derecha-libre entonces inicio
                        sur;
                    fin;
                fin;                   
                si frente-bloqueado entonces inicio
                    oeste;
                    mientras frente-libre hacer inicio
                        avanza;
                    fin;
                    sur;
                    mientras frente-libre hacer inicio
                        avanza;
                    fin;
                    oeste;
                fin;
                si no orientado-al-oeste entonces inicio
                    junta(0);
                fin;
            fin;
            calcetin(n);
        fin;
    fin;

    define-nueva-instruccion recoge-calcetin como inicio
        mientras no junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        si frente-bloqueado y no junto-a-zumbador entonces inicio
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            apagate;
        fin;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    oeste;
                    mientras frente-libre hacer inicio
                        avanza;
                    fin;
                    apagate;
                fin;
            fin sino inicio
                oeste;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                deja-zumbador;
                este;
                si frente-libre entonces inicio
                    avanza;
                fin;
            fin;
        fin;
        recoge-calcetin;
    fin;

    inicia-ejecucion
        ubicate1;
        junta(0);
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
        recoge-calcetin;
        apagate;
    termina-ejecucion
finalizar-programa
