iniciar-programa

    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion cuenta como inicio
        gira(2);
        mientras frente-libre hacer avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        mientras junto-a-zumbador hacer coge-zumbador;
        gira(2);
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        gira(2);
        avanza;
        gira(1);

        mientras frente-libre hacer inicio
            si junto-a-zumbador entonces coge-zumbador;
            avanza;
        fin;
        si junto-a-zumbador entonces coge-zumbador;
        gira(2);
        mientras frente-libre hacer avanza;

        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;

    fin;

    define-nueva-instruccion deja como inicio

        mientras junto-a-zumbador hacer coge-zumbador;
        gira(2);
        mientras frente-libre hacer avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        gira(1);

        mientras algun-zumbador-en-la-mochila hacer inicio
            avanza;
            deja-zumbador;
        fin;

        coge-zumbador;
        si no-junto-a-zumbador entonces inicio
            deja-zumbador;
        fin sino inicio
            coge-zumbador;
        fin;

        gira(2);
        si frente-libre entonces avanza;
        mientras frente-libre hacer inicio

            coge-zumbador;
            avanza;
        fin;

        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        gira(3);
        avanza;
        gira(3);
    fin;

    define-nueva-instruccion recorre como inicio

        mientras frente-libre o izquierda-libre hacer inicio
            si junto-a-zumbador entonces inicio
                deja;
            fin;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(3);
                si frente-libre entonces inicio
                    avanza;
                    gira(3);
                fin;
            fin;
        fin;

        si junto-a-zumbador entonces deja;

    fin;

    define-nueva-instruccion entra como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
        avanza;
        gira(3);
    fin;

    inicia-ejecucion
    entra;
    recorre;

    cuenta;
        apagate;
    termina-ejecucion
finalizar-programa
