iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion f(n) como inicio
        si frente-libre entonces  inicio
            avanza;
            f(n);
           avanza
        fin
        sino   inicio
            gira(1);
            repetir precede(n) veces
                avanza;
            deja-zumbador;
            gira(2);
            mientras frente-libre hacer
                avanza;
            gira(3);
        fin;
    fin;
    define-nueva-instruccion mide(n) como inicio
        si frente-libre entonces inicio
            avanza;
            mide(n);
            avanza;
        fin
        sino inicio
            gira(1);
            f(n);
            gira(3);
        fin;
    fin;
    define-nueva-instruccion zumbador(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            zumbador(sucede(n));
        fin
        sino inicio
            gira(2);
            mide(n);
        fin;
    fin;
    define-nueva-instruccion vertical(x) como inicio
        si frente-libre entonces inicio
            avanza;
            vertical(sucede(x));
        fin
        sino inicio
            mientras no-orientado-al-sur hacer
                gira(1);
            mientras frente-libre hacer
                avanza;
            gira(2);
            repetir x veces inicio
                avanza;
                gira(3);
                mientras frente-libre hacer inicio
                    si frente-libre y no-junto-a-zumbador entonces inicio
                        avanza;
                    fin
                    sino inicio
                        si junto-a-zumbador entonces inicio
                            zumbador(0);
                        fin;
                    fin;
                fin;
                si junto-a-zumbador entonces
                    zumbador(0);
                si frente-bloqueado entonces inicio
                    gira(2);
                    mientras frente-libre hacer
                        avanza;
                    gira(3);
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion calcetines(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
                si frente-libre entonces
                    avanza;
                calcetines(n);
            fin
            sino inicio
                si frente-libre entonces
                    avanza;
                calcetines(sucede(n));
            fin;
        fin
        sino inicio
            si frente-libre entonces inicio
                avanza;
                calcetines(n);
            fin
            sino inicio
                gira(2);
                mientras frente-libre hacer
                    avanza;
                gira(2);
                si junto-a-zumbador entonces
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                        avanza;
                        repetir 2 veces
                            deja-zumbador;
                        gira(2);
                        avanza;
                        repetir n veces
                            deja-zumbador;
                        apagate;
                    fin;
                repetir n veces
                    deja-zumbador;
                apagate;
            fin;
        fin;
    fin;
    inicia-ejecucion
        mientras no-orientado-al-norte hacer
            gira(1);
        vertical(0);
        mientras no-orientado-al-sur hacer
                gira(1);
        mientras frente-libre hacer
                avanza;
        gira(1);
        si frente-libre entonces
            calcetines(0);
        apagate;
    termina-ejecucion
finalizar-programa
