iniciar-programa
define-nueva-instruccion gira(t) como
    repetir t veces
        gira-izquierda;
define-nueva-instruccion arco como inicio
    gira(2);
    mientras frente-libre hacer avanza;
    gira(1);
    avanza;
    gira(1);
fin;
define-nueva-instruccion regresar como inicio
    gira(2);
    mientras frente-libre hacer avanza;
    gira(3);
    mientras frente-libre hacer avanza;
    gira(3);
    mientras no-junto-a-zumbador hacer inicio
        si frente-libre entonces inicio
            avanza;
        fin
        sino inicio
            si derecha-bloqueada entonces apagate;
            arco;
        fin;
    fin;
    si frente-bloqueado y derecha-bloqueada entonces apagate;
fin;
define-nueva-instruccion encuentra(x) como inicio
    si frente-bloqueado y derecha-bloqueada entonces inicio
        deja-zumbador;
        gira(1);
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        gira(2);
        avanza;
        gira(1);
        regresar;
    fin
    sino inicio
        si junto-a-zumbador entonces inicio
            repetir x veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin
                sino inicio
                    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                    repetir x veces coge-zumbador;
                    si frente-libre entonces inicio
                        avanza;
                    fin
                    sino arco;
                    encuentra(x);
                    sal-de-instruccion;
                fin;
            fin;
            si junto-a-zumbador entonces inicio
                repetir x veces deja-zumbador;
            fin
            sino inicio
                gira(3);
                mientras frente-libre hacer avanza;
                gira(1);
                mientras frente-libre hacer avanza;
                gira(1);
                avanza;
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                gira(2);
                avanza;
                gira(1);
                regresar;
                sal-de-instruccion;
            fin;
        fin;
        si frente-libre entonces inicio
            avanza;
        fin
        sino inicio
            arco;
        fin;
        encuentra(x);
    fin;
fin;
define-nueva-instruccion cuenta(u) como inicio
    mientras no orientado-al-sur hacer gira(1);
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        cuenta(sucede(u));
    fin
    sino inicio
        encuentra(u);
        cuenta(0);
    fin;
fin;
    inicia-ejecucion
    mientras no orientado-al-sur hacer gira(1);
    regresar;
    cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
