iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;
    define-nueva-instruccion regresarInicio como inicio
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        gira(2);
    fin;
    define-nueva-instruccion vaciarMochila como inicio
        gira(1);
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        gira(2);
        avanza;
        gira(3);
        avanza;
    fin;
    define-nueva-instruccion cambiarFila como inicio
        si izquierda-libre entonces inicio
            gira(1);
            avanza;
            gira(1);
            mientras frente-libre hacer avanza;
            gira(2);
        fin sino inicio
            (*No encontramos el par*)
            regresarInicio;
            gira(3);
            avanza;
            deja-zumbador;
            vaciarMochila;
        fin;
    fin;
    define-nueva-instruccion buscarBeeper como inicio
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
        si no-junto-a-zumbador y izquierda-bloqueada y ningun-zumbador-en-la-mochila entonces inicio
            (*Dimos la ultima pasada*)
            regresarInicio;
            gira(3);
            avanza;
            gira(1);
            avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
            apagate;
        fin sino inicio
            si no-junto-a-zumbador entonces inicio
                cambiarFila;
                si orientado-al-este entonces buscarBeeper;
            fin;
        fin;
    fin;
    define-nueva-instruccion comparar(x) como inicio
        si no si-es-cero(x) entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                comparar(precede(x));
                (*Si no es el mismo que el calcetin*)
                si orientado-al-este entonces deja-zumbador;
            fin;
        fin sino inicio
            (*Encontramos el par del calcetin*)
            si no-junto-a-zumbador entonces inicio
                regresarInicio;
                gira(3);
                avanza;
                vaciarMochila;
            fin
        fin;
    fin;
    define-nueva-instruccion contar(cuantos) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            contar(sucede(cuantos));
        fin sino inicio
            buscarBeeper;
            mientras junto-a-zumbador hacer inicio
                comparar(cuantos);
                si junto-a-zumbador entonces inicio
                    si frente-libre entonces inicio
                        avanza;
                    fin sino inicio
                        cambiarFila;
                    fin;
                    si orientado-al-este entonces buscarBeeper;
                fin;
            fin;
        fin;
    fin;
    inicia-ejecucion
        mientras no-orientado-al-norte hacer gira-izquierda;
        avanza;
        mientras orientado-al-norte hacer inicio
            gira(3);
            buscarBeeper;
            si junto-a-zumbador entonces contar(0);
        fin;
    termina-ejecucion
finalizar-programa
