iniciar-programa
define-nueva-instruccion calce(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        calce(sucede(n));
    fin
    sino inicio
        mientras frente-libre hacer avanza;
        repetir 3 veces gira-izquierda;
        mientras frente-libre hacer avanza;
        repetir 3 veces gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        avanza;
        gira-izquierda;
        repetir n veces avanza;
        deja-zumbador;
        repetir 2 veces gira-izquierda;
        mientras frente-libre hacer avanza;
        repetir 3 veces gira-izquierda;
        avanza;
        repetir 3 veces gira-izquierda;
    fin;
fin;
define-nueva-instruccion busca como inicio
    mientras frente-libre y no-junto-a-zumbador hacer avanza;
    si frente-bloqueado y no-junto-a-zumbador entonces inicio
        repetir 2 veces gira-izquierda;
        mientras frente-libre hacer avanza;
        repetir 3 veces gira-izquierda;
        si frente-libre entonces avanza
        sino inicio
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            repetir 2 veces gira-izquierda;
            mientras frente-libre hacer avanza;
            gira-izquierda;
            mientras frente-libre hacer avanza;
            repetir 2 veces gira-izquierda;
            mientras frente-libre hacer inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces deja-zumbador;
                fin;
                avanza;
            fin;
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            apagate;
        fin;
        repetir 3 veces gira-izquierda;
        busca;
    fin;
    si junto-a-zumbador entonces inicio
        calce(0);
        busca;
    fin;
fin;
    inicia-ejecucion
    mientras no-orientado-al-norte hacer gira-izquierda;
    avanza;
    repetir 3 veces gira-izquierda;
    busca;
        apagate;
    termina-ejecucion
finalizar-programa
