iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-prototipo-instruccion busca(x);
    define-nueva-instruccion camina(x) como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            busca(x);
            sur;
            avanza;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            busca(x);
            oeste;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            busca(x);
            norte;
            avanza;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            busca(x);
            este;
            avanza;
        fin;
        apagate;
    fin;
    define-nueva-instruccion agarra(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            agarra(sucede(x));
        fin sino inicio
            repetir x veces deja-zumbador;
            camina(x);
        fin;
    fin;
    define-nueva-instruccion menor(x) como inicio
        si junto-a-zumbador y no si-es-cero(x)entonces inicio
            coge-zumbador;
            menor(precede(x));
            deja-zumbador;
        fin sino inicio
            si no si-es-cero(x) y no-junto-a-zumbador entonces inicio
                sur;
            fin;
        fin;
    fin;
    define-nueva-instruccion busca(x) como inicio

            norte;
            menor(x);
            si orientado-al-sur entonces agarra(0);
        fin;

    inicia-ejecucion
        busca(100);
        apagate;
    termina-ejecucion
finalizar-programa
