iniciar-programa
define-nueva-instruccion deja-zumbadores como
inicio
    si junto-a-zumbador y frente-libre entonces
    inicio
        avanza;
        deja-zumbadores;
        avanza;
    fin
    sino
    inicio
        mientras algun-zumbador-en-la-mochila hacer
            deja-zumbador;
        repetir 2 veces
            gira-izquierda;
    fin;
fin;
define-nueva-instruccion zumbadores(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        zumbadores(sucede(x));
    fin
    sino
    inicio
        repetir x veces
            deja-zumbador;
        si frente-libre entonces
            avanza
        sino
        inicio
            mientras frente-bloqueado hacer
                gira-izquierda;
            avanza;
        fin;
        repetir x veces
            si junto-a-zumbador entonces
                coge-zumbador;
        si junto-a-zumbador entonces
        inicio
            repetir x veces
                deja-zumbador;
            repetir 2 veces
                gira-izquierda;
            avanza;       
            repetir 3 veces
                gira-izquierda;
        fin;
    fin;

fin;
define-nueva-instruccion checa(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        zumbadores(0);
        si junto-a-zumbador y no si-es-cero(x) entonces
            checa(precede(x))
        sino
        si si-es-cero(x) entonces
            apagate;
    fin;
fin;
define-nueva-instruccion orientate como
inicio
    si no orientado-al-norte entonces
    inicio
        gira-izquierda;
        orientate;
        repetir 3 veces
            gira-izquierda;
    fin
    sino
    inicio
        deja-zumbadores;
        repetir 2 veces
            gira-izquierda;
    fin;
fin;
define-nueva-instruccion compara(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        compara(sucede(x));
    fin
    sino
    inicio
        orientate;
        si frente-libre entonces
            avanza
        sino
        inicio
            mientras frente-bloqueado hacer
                gira-izquierda;
            avanza;
        fin;
        si junto-a-zumbador entonces
        inicio
            repetir x veces
            inicio
                si junto-a-zumbador entonces
                    coge-zumbador;
            fin;
            si no junto-a-zumbador entonces
            inicio
                mientras algun-zumbador-en-la-mochila hacer
                    deja-zumbador;
                compara(0);
            fin
            sino
            inicio
                mientras algun-zumbador-en-la-mochila hacer
                    deja-zumbador;
                repetir 2 veces
                    gira-izquierda;
                avanza;
                repetir 2 veces
                    gira-izquierda;
                checa(4);
                si no junto-a-zumbador entonces
                inicio
                    mientras algun-zumbador-en-la-mochila hacer
                        deja-zumbador;
                    compara(0);
                fin;
            fin;
        fin;
    fin;
fin;
    inicia-ejecucion
    compara(0);
        apagate;
    termina-ejecucion
finalizar-programa
