iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion cuentaS como inicio
        si frente-libre entonces inicio
            avanza;
            cuentaS;
        fin sino inicio
            norte;
            repetir 15 veces avanza;
        fin;
        deja-zumbador;
    fin;
    define-nueva-instruccion posActual como inicio
        norte;
        avanza;
        deja-zumbador;
        sur;
        avanza;
        este;
    fin;
    define-nueva-instruccion multiplos(a) como inicio
        mientras frente-libre hacer inicio
            repetir a veces si frente-libre entonces inicio
                avanza;
            fin;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion regresar como inicio
        norte;
        avanza;
        oeste;
        mientras no-junto-a-zumbador hacer avanza;
        coge-zumbador;
        sur;
        avanza;
        este;
    fin;
    define-nueva-instruccion criba(n) como inicio
        si no-orientado-al-oeste entonces inicio
            si no-junto-a-zumbador entonces inicio
                posActual;
                multiplos(n);
                regresar;
            fin;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                oeste;
            fin;
            criba(sucede(n));
        fin;
    fin;
    define-nueva-instruccion vuelveCamino como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            vuelveCamino;
            avanza;
        fin sino inicio
            corre;
            norte;
        fin;
    fin;
    define-nueva-instruccion irmonton como inicio
        oeste;
        corre;
        sur;
        avanza;
        este;
        mientras no-junto-a-zumbador hacer avanza;
        coge-zumbador;
        sur;
    fin;
    define-nueva-instruccion esprimo(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            esprimo(sucede(n));
        fin sino inicio
            sur;
            cuentaS;
            oeste;
            corre;
            norte;
            avanza;
            este;
            repetir precede(n) veces avanza;
            si no-junto-a-zumbador entonces inicio
                irmonton;
                vuelveCamino;
            fin sino inicio
                irmonton;
                vuelveCamino;
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion busqueda como inicio
        si junto-a-zumbador entonces inicio
            esprimo(0);
            si no-junto-a-zumbador entonces inicio
                norte;
                si frente-libre entonces inicio
                    avanza;
                    busqueda;
                    sur;
                    avanza;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    busqueda;
                    oeste;
                    avanza;
                fin;
                sur;
                si frente-libre entonces inicio
                    avanza;
                    busqueda;
                    norte;
                    avanza;
                fin;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    busqueda;
                    este;
                    avanza;
                fin;
                apagate;
            fin;
        fin;
    fin;
    inicia-ejecucion
        sur;
        cuentaS;
        oeste;
        corre;
        norte;
        avanza;
        este;
        deja-zumbador;
        este;
        avanza;
        criba(2);
        irmonton;
        vuelveCamino;
        busqueda;
        apagate;
    termina-ejecucion
finalizar-programa
