iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-prototipo-instruccion busca;
    define-nueva-instruccion acaba como inicio
        repetir 2 veces gira-izquierda;
        avanza;
        deja-zumbador;
        apagate;
    fin;
    define-nueva-instruccion regresa como inicio
         repetir 2 veces gira-izquierda;
         avanza;
    fin;
    define-nueva-instruccion revisaS como inicio
        sur;
        si frente-libre entonces inicio
            avanza;
            si izquierda-libre entonces inicio
                acaba;
            fin sino inicio
            regresa;
            fin;
        fin;
    fin;
    define-nueva-instruccion revisaN como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            si derecha-libre entonces inicio
                acaba;
            fin sino inicio
                regresa;
                revisaS;
            fin;
        fin sino inicio
            revisaS;
        fin;
    fin;
    define-nueva-instruccion es-salida como inicio
        este;
        si frente-libre entonces inicio
            revisaN;
        fin;
        este;
    fin;
    define-nueva-instruccion camina como inicio
        este;
        si frente-libre entonces inicio
            avanza;
            si algun-zumbador-en-la-mochila entonces es-salida;
            busca;
            oeste;
            avanza;
        fin;
        norte;
        si frente-libre entonces inicio
            avanza;
            busca;
            sur;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            busca;
            norte;
            avanza;
        fin;
    fin;
    define-prototipo-instruccion busca-entrada;
    define-nueva-instruccion busca como inicio
        si no junto-a-zumbador y algun-zumbador-en-la-mochila entonces inicio
            deja-zumbador;
            camina;
            coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion muevete como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            busca-entrada;
            sur;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            busca-entrada;
            norte;
            avanza;
        fin;
    fin;
    define-nueva-instruccion entra como inicio
        este;
        avanza;
        si algun-zumbador-en-la-mochila entonces es-salida;
        busca;
        oeste;
        avanza;
        este;
    fin;
    define-nueva-instruccion checaS como inicio
        si frente-libre entonces inicio
            avanza;
            si izquierda-libre entonces inicio
                norte;
                avanza;
                este;
                avanza;
                si derecha-bloqueada entonces inicio
                    si algun-zumbador-en-la-mochila entonces es-salida;
                    busca;
                    oeste;
                    avanza;
                    este;
                fin sino inicio
                    regresa;
                fin;
            fin sino inicio
                regresa;
                entra;
            fin;
        fin sino inicio
            entra;
        fin;
    fin;
    define-nueva-instruccion checaN como inicio
        avanza;
        si derecha-libre entonces inicio
            sur;
            avanza;
            este;
            avanza;
            si izquierda-bloqueada entonces inicio
                si algun-zumbador-en-la-mochila entonces es-salida;
                busca;
                oeste;
                avanza;
                este;
            fin sino inicio
                regresa;
            fin;
        fin sino inicio
            regresa;
            sur;
            checaS;
        fin;
    fin;
    define-nueva-instruccion valido como inicio
         si frente-libre entonces inicio
             norte;
             si frente-libre entonces inicio
                 checaN;
             fin sino inicio
                 sur;
                 checaS;
             fin;
        fin;
    fin;
    define-nueva-instruccion busca-entrada como inicio
        si no-junto-a-zumbador y algun-zumbador-en-la-mochila entonces inicio
            deja-zumbador;
            este;
            valido;
            si no-orientado-al-oeste entonces muevete;
            coge-zumbador;
        fin;
    fin;
    inicia-ejecucion

        busca-entrada;
        apagate;
    termina-ejecucion
finalizar-programa
