iniciar-programa


    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion orientar como inicio
        sur;
        mientras frente-libre hacer avanza;
        este;
        mientras frente-libre hacer avanza;
        oeste;
    fin;

    define-nueva-instruccion revisar como inicio
        mientras no orientado-al-sur hacer inicio
            norte;
            si junto-a-zumbador entonces inicio
                mientras junto-a-zumbador y frente-libre hacer avanza;
                sur;
                avanza;
                norte;
                avanza;
                avanza;
                oeste;
            fin sino inicio
                norte;
                avanza;
                avanza;
                oeste;
            fin;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    norte;
                    mientras junto-a-zumbador y frente-libre hacer avanza;
                    sur;
                    avanza;
                    coge-zumbador;
                    este;
                    avanza;
                    sur;
                    mientras no junto-a-zumbador y frente-libre hacer avanza;
                    norte;
                    avanza;
                    deja-zumbador;
                    oeste;
                    avanza;
                    norte;
                    mientras junto-a-zumbador y frente-libre hacer avanza;
                fin sino inicio
                    sur;
                    mientras frente-libre hacer avanza;
                fin;
            fin sino inicio
                sur;
            fin;
        fin;
    fin;

    define-nueva-instruccion erosion como inicio
        mientras algun-zumbador-en-la-mochila hacer inicio
            mientras no junto-a-zumbador y frente-libre hacer avanza;
            si frente-bloqueado y no junto-a-zumbador entonces inicio
                norte;
                mientras frente-libre hacer avanza;
                deja-zumbador;
                orientar;
            fin sino inicio
                si junto-a-zumbador entonces inicio
                    norte;
                    revisar;
                    oeste;
                    si frente-libre entonces inicio
                        si no junto-a-zumbador entonces avanza;
                    fin sino inicio
                        norte;
                        mientras frente-libre hacer avanza;
                        deja-zumbador;
                        orientar;
                    fin;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        si algun-zumbador-en-la-mochila entonces inicio
            orientar;
            erosion;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
