iniciar-programa
   define-nueva-instruccion gira(n) como inicio
      repetir n veces
         gira-izquierda;
   fin;
   define-nueva-instruccion norte como inicio
      mientras no-orientado-al-norte hacer
         gira(1);
   fin;
   define-nueva-instruccion sur como inicio
      mientras no-orientado-al-sur hacer
         gira(1);
   fin;
   define-nueva-instruccion este como inicio
      mientras no-orientado-al-este hacer
         gira(1);
   fin;
   define-nueva-instruccion oeste como inicio
      mientras no-orientado-al-oeste hacer
         gira(1);
   fin;
   define-nueva-instruccion zumbador(n) como inicio
      si junto-a-zumbador entonces inicio
         norte;
         mientras junto-a-zumbador hacer
            avanza;
         avanza;
         oeste;
         avanza;
         si junto-a-zumbador entonces inicio
            zumbador(sucede(n));
         fin
         sino inicio
            este;
            avanza;
            sur;
            avanza;
            avanza;
            coge-zumbador;
            este;
            repetir n veces
               avanza;
            sur;
            si frente-libre entonces inicio
               mientras no-junto-a-zumbador hacer
                  avanza;
               norte;
               avanza;
            fin;
            deja-zumbador;
            sur;
            mientras frente-libre hacer
               avanza;
            oeste;
            repetir sucede(n) veces
               avanza;
         fin;
      fin;
   fin;
   define-nueva-instruccion erosion como inicio
      mientras orientado-al-oeste hacer inicio
         mientras no-junto-a-zumbador y frente-libre hacer
            avanza;
         si junto-a-zumbador y frente-libre entonces inicio
            zumbador(0);
         fin
         sino inicio
            este;
         fin;
      fin;
   fin;
   inicia-ejecucion
      mientras algun-zumbador-en-la-mochila hacer inicio
         deja-zumbador;
         este;
         mientras frente-libre hacer
            avanza;
         oeste;
         erosion;
      fin;
      mientras junto-a-zumbador hacer
         coge-zumbador;
      apagate;
   termina-ejecucion
finalizar-programa