iniciar-programa
    define-nueva-instruccion gira(z) como inicio
        repetir z veces gira-izquierda;
    fin;
    define-nueva-instruccion menos como inicio
        gira(1);
        mientras frente-libre hacer avanza;
        gira(1);
        coge-zumbador;
    fin;
    define-nueva-instruccion comprobar como inicio
        avanza;
        si junto-a-zumbador entonces inicio
            gira(1);
            mientras junto-a-zumbador y frente-libre hacer avanza;
            avanza;
            gira(1);
            avanza;
            si junto-a-zumbador entonces menos sino inicio
                gira(1);
                mientras frente-libre hacer avanza;
                gira(1);
            fin;
        fin;
    fin;
    define-nueva-instruccion erosion como inicio
        deja-zumbador;
        gira(2);
        mientras junto-a-zumbador y frente-libre hacer avanza;
        si no-junto-a-zumbador entonces inicio
            gira(2);
            avanza;
        fin;
        coge-zumbador;
        mientras no-orientado-al-este hacer gira-izquierda;
        avanza;
        gira(3);
        mientras no-junto-a-zumbador hacer avanza;
        gira(2);
        avanza;
        deja-zumbador;
        gira(2);
        mientras frente-libre hacer avanza;
        gira(2);
        avanza;
        gira(1);
        si frente-libre entonces avanza;
    fin;
inicia-ejecucion
    mientras no-orientado-al-este hacer gira-izquierda;
    avanza;
    mientras algun-zumbador-en-la-mochila hacer inicio
        mientras frente-libre hacer inicio
            si junto-a-zumbador y frente-libre entonces comprobar;
            si frente-libre entonces avanza;
        fin;
        si frente-bloqueado entonces inicio
            gira(1);
            avanza;
            gira(1);
            mientras frente-libre hacer inicio
                mientras frente-libre y no-junto-a-zumbador hacer avanza;
                si frente-libre entonces inicio
                    gira(1);
                    avanza;
                    si no-junto-a-zumbador entonces erosion sino inicio
                        gira(2);
                        avanza;
                        gira(1);
                        si frente-libre entonces avanza;
                    fin;
                fin;
            fin;
            si frente-bloqueado entonces inicio
                gira(1);
                avanza;
                deja-zumbador;
            fin;
            si ningun-zumbador-en-la-mochila entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                gira(2);
                apagate;
            fin;
            gira(1);
            si frente-libre entonces avanza;
        fin;
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
