iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion checa como inicio
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                sur;
                si frente-libre entonces
                    avanza;
                si no-junto-a-zumbador entonces inicio
                    mientras frente-libre y no-junto-a-zumbador hacer
                        avanza;
                    gira (1);
                    si junto-a-zumbador entonces inicio
                       checa;
                    fin
                    sino inicio
                        oeste;
                        avanza;
                        norte;
                        mientras junto-a-zumbador hacer
                            avanza;
                        deja-zumbador;
                        este;
                        avanza;
                        sur;
                        mientras frente-libre hacer
                            avanza;
                        gira (2);
                        mientras junto-a-zumbador hacer
                            avanza;
                        este;
                    fin;
                fin
                sino inicio
                    oeste;
                    avanza;
                    norte;
                    mientras junto-a-zumbador hacer
                        avanza;
                    deja-zumbador;
                    sur;
                    mientras frente-libre hacer
                        avanza;
                    este;
                    avanza;
                fin;
            fin
            sino inicio
                oeste;
                avanza;
                norte;
                mientras junto-a-zumbador hacer
                    avanza;
                deja-zumbador;
                sur;
                mientras frente-libre hacer
                    avanza;
                este;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion cordillera como inicio
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        gira (1);
        mientras junto-a-zumbador hacer
            avanza;
        sur;
        si frente-libre entonces
            avanza;
        este;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            checa;
        fin;
        este;
    fin;
    define-nueva-instruccion erosion (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            erosion (sucede(n));
        fin
        sino inicio
            repetir n veces inicio
                mientras frente-libre hacer inicio
                    cordillera;
                fin;
                oeste;
                mientras frente-libre hacer
                    avanza;
                este;
            fin;
        fin;
    fin;
    inicia-ejecucion
        este;
        mientras algun-zumbador-en-la-mochila hacer
            deja-zumbador;
        erosion (0);
        apagate;
    termina-ejecucion
finalizar-programa